[arch-commits] Commit in python-bottle/repos (2 files)

[Felix Yan]

    Date: Tuesday, September 22, 2015 @ 09:09:26
  Author: fyan
Revision: 141450

archrelease: copy trunk to community-staging-any

Added:
  python-bottle/repos/community-staging-any/
  python-bottle/repos/community-staging-any/PKGBUILD
    (from rev 141449, python-bottle/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: python-bottle/repos/community-staging-any/PKGBUILD (from rev 141449, python-bottle/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2015-09-22 07:09:26 UTC (rev 141450)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Richard Murri <admin at richardmurri.com>
+# Contributor: Farhad Shahbazi <farhad at enthusiasm.cc>
+# Contributor: Felix Kaiser <felix.kaiser at fxkr.net>
+
+pkgbase=python-bottle
+pkgname=("python-bottle" "python2-bottle")
+pkgver=0.12.8
+pkgrel=2
+pkgdesc="A fast and simple micro-framework for small web-applications"
+arch=(any)
+url="http://bottlepy.org"
+license=('MIT')
+options=(!emptydirs)
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-mako' 'python2-mako' 'python-jinja' 'python2-jinja'
+              'python-cherrypy' 'python2-cherrypy' 'python-twisted'
+              'python2-twisted' 'python-tornado' 'python2-tornado'
+              'python2-paste' 'python2-gevent')
+source=("git+https://github.com/defnull/bottle.git#tag=${pkgver}")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a bottle{,-py2}
+  sed -i "1s/python/python2/" bottle-py2/bottle.py
+}
+
+check() {
+  cd "$srcdir/bottle"
+  # https://github.com/bottlepy/bottle/issues/791
+  python test/testall.py || warning 'Tests failed'
+
+  cd "$srcdir/bottle-py2"
+  python2 test/testall.py
+}
+
+package_python-bottle() {
+  depends=('python3')
+
+  cd bottle
+  python3 setup.py install --root="${pkgdir}" --optimize=1
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-bottle() {
+  depends=('python2')
+
+  cd bottle-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+  # deal with conflict with python-bottle's /usr/bin/bottle.py
+  mv "$pkgdir/usr/bin/bottle.py"{,2}
+}