[arch-commits] Commit in python-sympy/repos (2 files)

[Felix Yan]

    Date: Tuesday, September 22, 2015 @ 11:33:39
  Author: fyan
Revision: 141454

archrelease: copy trunk to community-staging-any

Added:
  python-sympy/repos/community-staging-any/
  python-sympy/repos/community-staging-any/PKGBUILD
    (from rev 141453, python-sympy/trunk/PKGBUILD)

----------+
 PKGBUILD |   69 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

Copied: python-sympy/repos/community-staging-any/PKGBUILD (from rev 141453, python-sympy/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2015-09-22 09:33:39 UTC (rev 141454)
@@ -0,0 +1,69 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>  
+# Contributor: Peter Garceau <RockyChimp at gmail.com>
+
+pkgbase=python-sympy
+pkgname=('python2-sympy' 'python-sympy')
+pkgver=0.7.6.1.20150913
+_commit=556af5800d3821bb9920a735ceac5e5cd24a97b6
+pkgrel=1
+arch=('any')
+pkgdesc='Symbolic manipulation package (Computer Algebra System), written in pure Python'
+url='http://sympy.org/en/index.html'
+license=('BSD')
+makedepends=('python2-mpmath' 'python-mpmath' 'python-setuptools' 'python2-setuptools' 'git')
+#source=("git+https://github.com/sympy/sympy.git#tag=sympy-${pkgver}"
+source=("git+https://github.com/sympy/sympy.git#commit=$_commit")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a sympy py3-sympy
+}
+
+build() {
+  cd sympy
+  python2 setup.py build
+
+  cd ../py3-sympy
+  python3 setup.py build
+}
+
+check() {
+  # Broken, waiting for upstream fixes.
+
+  cd sympy
+  python2 setup.py test || warning "Exit code: $?"
+
+  cd ../py3-sympy
+  python3 setup.py test || warning "Exit code: $?"
+}
+
+package_python2-sympy() {
+  depends=('python2-mpmath')
+  optdepends=('python2-pyglet: plotting'
+              'ipython2: user friendly interface for isympy')
+
+  cd sympy
+
+  python2 setup.py install --root "${pkgdir}" --optimize=1
+
+  install -D -m644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}
+
+package_python-sympy() {
+  depends=('python-mpmath')
+  optdepends=('ipython: user friendly interface for isympy')
+
+  cd py3-sympy
+
+  python3 setup.py install --root "${pkgdir}" --optimize=1
+
+  # rename files that exists in both 'python2-sympy' and 'python-sympy'
+  mv "${pkgdir}"/usr/bin/isympy{,-py3}
+  mv "${pkgdir}"/usr/share/man/man1/isympy{,-py3}.1
+
+  install -D -m644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}