[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Sunday, April 10, 2016 @ 14:53:25
  Author: fyan
Revision: 170087

addpkg: python-profilestats 2.0-1

Added:
  python-profilestats/
  python-profilestats/repos/
  python-profilestats/trunk/
  python-profilestats/trunk/PKGBUILD

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Added: python-profilestats/trunk/PKGBUILD
===================================================================
--- python-profilestats/trunk/PKGBUILD	                        (rev 0)
+++ python-profilestats/trunk/PKGBUILD	2016-04-10 12:53:25 UTC (rev 170087)
@@ -0,0 +1,40 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-profilestats
+pkgname=('python-profilestats' 'python2-profilestats')
+pkgver=2.0
+pkgrel=1
+pkgdesc="Decorator for profiling individual functions and converting profiling data to the kcachegrind/qcachegrind format."
+arch=('any')
+license=('BSD')
+url="https://pypi.python.org/pypi/profilestats"
+makedepends=('python-setuptools' 'python2-setuptools' 'pyprof2calltree' 'python2-pyprof2calltree' 'git')
+source=("git+https://github.com/hannosch/profilestats.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a profilestats{,-py2}
+}
+
+build() {
+  cd "$srcdir"/profilestats
+  python setup.py build
+
+  cd "$srcdir"/profilestats-py2
+  python2 setup.py build
+}
+
+package_python-profilestats() {
+  depends=('python-setuptools' 'pyprof2calltree')
+
+  cd profilestats
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-profilestats() {
+  depends=('python2-setuptools' 'python2-pyprof2calltree')
+
+  cd profilestats-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}


Property changes on: python-profilestats/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property