[arch-commits] Commit in (runc runc/repos runc/trunk runc/trunk/PKGBUILD)
Sébastien Luttringer
seblu at archlinux.org
Tue Apr 26 00:02:29 UTC 2016
Date: Tuesday, April 26, 2016 @ 02:02:29
Author: seblu
Revision: 171864
Add runc
Added:
runc/
runc/repos/
runc/trunk/
runc/trunk/PKGBUILD
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Added: runc/trunk/PKGBUILD
===================================================================
--- runc/trunk/PKGBUILD (rev 0)
+++ runc/trunk/PKGBUILD 2016-04-26 00:02:29 UTC (rev 171864)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Sébastien "Seblu" Luttringer
+
+pkgname=runc
+pkgver=0.1.0
+pkgrel=1
+pkgdesc='CLI tool for managing OCI compliant containers'
+arch=('x86_64')
+url='https://runc.io/'
+license=('Apache')
+depends=('glibc' 'libseccomp')
+makedepends=('git' 'go' 'go-md2man')
+source=("git+https://github.com/opencontainers/runc#tag=v$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+ cd runc
+ # apply patch from the source array (should be a pacman feature)
+ local filename
+ for filename in "${source[@]}"; do
+ if [[ "$filename" =~ \.patch$ ]]; then
+ msg2 "Applying patch $filename"
+ patch -p1 -N -i "$srcdir/$filename"
+ fi
+ done
+ :
+}
+
+build() {
+ mkdir -p src/github.com/opencontainers
+ cd src/github.com/opencontainers
+ ln -fs "$srcdir/runc"
+ cd runc
+ export GOPATH="$srcdir"
+ make
+ man/md2man-all.sh 2>/dev/null
+}
+
+#check() {
+# cd runc
+# make localtest
+#}
+
+package() {
+ cd runc
+ install -Dm755 runc "$pkgdir/usr/bin/runc"
+ # man pages
+ install -dm755 "$pkgdir/usr/share/man"
+ mv man/man*/ "$pkgdir/usr/share/man"
+}
+
+# vim:set ts=2 sw=2 et:
Property changes on: runc/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list