[arch-commits] Commit in (3 files)
Maxime Gauduin
alucryd at archlinux.org
Sat Aug 20 10:38:22 UTC 2016
Date: Saturday, August 20, 2016 @ 10:38:22
Author: alucryd
Revision: 187175
Add libcurl-gnutls
Added:
libcurl-gnutls/
libcurl-gnutls/trunk/
libcurl-gnutls/trunk/PKGBUILD
----------+
PKGBUILD | 56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 56 insertions(+)
Added: libcurl-gnutls/trunk/PKGBUILD
===================================================================
--- libcurl-gnutls/trunk/PKGBUILD (rev 0)
+++ libcurl-gnutls/trunk/PKGBUILD 2016-08-20 10:38:22 UTC (rev 187175)
@@ -0,0 +1,56 @@
+# $Id$
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Lizao (Larry) Li <lzlarryli at gmail.com>
+
+pkgname=libcurl-gnutls
+pkgver=7.50.1
+pkgrel=1
+pkgdesc='An URL retrieval library'
+arch=('i686' 'x86_64')
+url='http://curl.haxx.se'
+license=('MIT')
+depends=('curl' 'glibc' 'gnutls' 'nettle' 'zlib'
+ 'libssh2.so')
+options=('strip')
+source=("http://curl.haxx.se/download/curl-${pkgver}.tar.gz"{,.asc})
+sha256sums=('3e392cf600822b817be82d9080b377fcbab70538d5a8bf525a1cd66e157b99ea'
+ 'SKIP')
+validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2') # Daniel Stenberg
+
+build() {
+ cd curl-${pkgver}
+
+ ./configure \
+ --prefix='/usr' \
+ --disable-ldap \
+ --disable-ldaps \
+ --disable-manual \
+ --disable-versioned-symbols \
+ --enable-ipv6 \
+ --enable-threaded-resolver \
+ --without-gssapi \
+ --without-libidn \
+ --without-ssl \
+ --with-gnutls='/usr' \
+ --with-random='/dev/urandom' \
+ --with-ca-bundle='/etc/ssl/certs/ca-certificates.crt'
+
+ make -C lib
+}
+
+package() {
+ cd curl-${pkgver}
+
+ make -C lib DESTDIR="${pkgdir}" install
+
+ mv "${pkgdir}"/usr/lib/libcurl{,-gnutls}.so.4.4.0
+ rm "${pkgdir}"/usr/lib/libcurl.{a,so}*
+ for version in 3 4.0.0 4.1.0 4.2.0 4.3.0; do
+ ln -s libcurl-gnutls.so.4.4.0 "${pkgdir}"/usr/lib/libcurl-gnutls.so.${version}
+ done
+
+ install -dm 755 "${pkgdir}"/usr/share/licenses
+ ln -s curl "${pkgdir}"/usr/share/licenses/libcurl-gnutls
+}
+
+# vim: ts=2 sw=2 et:
Property changes on: libcurl-gnutls/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list