[arch-commits] Commit in kdenlive (trunk trunk trunk/PKGBUILD)

[Felix Yan]

    Date: Sunday, August 21, 2016 @ 03:34:40
  Author: felixonmars
Revision: 274404

upgpkg: kdenlive 16.08.0-1

Upstream release

Added:
  kdenlive/trunk/
  kdenlive/trunk/PKGBUILD
Deleted:
  kdenlive/trunk/

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Added: trunk/PKGBUILD
===================================================================
--- trunk/PKGBUILD	                        (rev 0)
+++ trunk/PKGBUILD	2016-08-21 03:34:40 UTC (rev 274404)
@@ -0,0 +1,46 @@
+# $Id$
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Zuf <kontakt.zuf at gmail.com>
+# Contributor: Darwin Bautista <djclue917 at gmail.com>
+# Contributor: Gustavo Alvarez <sl1pkn07 at gmail.com>
+
+pkgname=kdenlive
+pkgver=16.08.0
+pkgrel=1
+pkgdesc="A non-linear video editor for Linux using the MLT video framework"
+arch=(i686 x86_64)
+url="http://www.kdenlive.org/"
+license=(GPL)
+groups=(kde-applications kdemultimedia)
+depends=(knewstuff knotifyconfig kded kfilemetadata qt5-webkit mlt glu sdl_image hicolor-icon-theme qt5-quickcontrols)
+makedepends=(extra-cmake-modules kdoctools v4l-utils python)
+optdepends=('ffmpeg: for FFmpeg plugin'
+            'cdrkit: for creation of DVD ISO images'
+            'dvdauthor: for creation of DVD'
+            'dvgrab: for firewire capture'
+            'libdv: for webcam capture (if FFmpeg is not installed)'
+            'recordmydesktop: for screen capture'
+            'xine-ui: for DVD preview'
+            'plasma-desktop: theme configuration')
+source=("http://download.kde.org/stable/applications/${pkgver}/src/$pkgname-${pkgver}.tar.xz")
+md5sums=('007ba69109b1775e7bce2b23b7dbf89c')
+
+prepare(){
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DKDE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  make -C build DESTDIR="${pkgdir}" install
+}
+


Property changes on: kdenlive/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property