[arch-commits] Commit in (4 files)

[Bartłomiej Piotrowski]

    Date: Saturday, December 10, 2016 @ 18:26:08
  Author: bpiotrowski
Revision: 283012

newpkg: asciidoctor 1.5.5-2

Added:
  asciidoctor/
  asciidoctor/repos/
  asciidoctor/trunk/
  asciidoctor/trunk/PKGBUILD

----------+
 PKGBUILD |   34 ++++++++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)

Added: asciidoctor/trunk/PKGBUILD
===================================================================
--- asciidoctor/trunk/PKGBUILD	                        (rev 0)
+++ asciidoctor/trunk/PKGBUILD	2016-12-10 18:26:08 UTC (rev 283012)
@@ -0,0 +1,34 @@
+# $Id$
+# Maintainer:
+# Contributor: Stefan Tatschner <rumpelsepp at sevenbyte.org>
+# Contributor: Nick Østergaard <oe.nick at gmail dot com>
+# Contributor: Nicolas Bigaouette <nbigaouette at chemcomp.com>
+
+pkgname=asciidoctor
+pkgver=1.5.5
+pkgrel=2
+pkgdesc='An implementation of AsciiDoc in Ruby'
+arch=('any')
+url='http://asciidoctor.org'
+license=('MIT')
+depends=('ruby')
+options=(!emptydirs)
+source=(https://rubygems.org/downloads/${pkgname}-${pkgver}.gem)
+noextract=($pkgname-$pkgver.gem)
+sha1sums=('b228d1cc7dad4d773ce0ca2aa35911403725b2ba')
+
+package() {
+    local _gemdir="$(ruby -e 'puts Gem.default_dir')"
+
+    gem install --ignore-dependencies --no-user-install --verbose \
+        -i "$pkgdir/$_gemdir" -n "$pkgdir/usr/bin" \
+        "$pkgname-$pkgver.gem"
+
+    install -Dm644 "$pkgdir/$_gemdir/gems/$pkgname-$pkgver/LICENSE.adoc" \
+        "$pkgdir/usr/share/licenses/$pkgname/LICENSE.adoc"
+    install -Dm644 "$pkgdir/$_gemdir/gems/$pkgname-$pkgver/man/asciidoctor.1" \
+        "$pkgdir/usr/share/man/man1/asciidoctor.1"
+
+    rm "$pkgdir/$_gemdir/cache/$pkgname-$pkgver.gem"
+    rm -rf "$pkgdir/$_gemdir/gems/$pkgname-$pkgver/man"
+}


Property changes on: asciidoctor/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property