[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Tuesday, December 13, 2016 @ 07:44:30
  Author: felixonmars
Revision: 199172

addpkg: python-cram 0.7-1

Added:
  python-cram/
  python-cram/repos/
  python-cram/trunk/
  python-cram/trunk/PKGBUILD

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Added: python-cram/trunk/PKGBUILD
===================================================================
--- python-cram/trunk/PKGBUILD	                        (rev 0)
+++ python-cram/trunk/PKGBUILD	2016-12-13 07:44:30 UTC (rev 199172)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
+# Contributor: Thomas S Hatch <thatch45 at gmail.com>
+
+pkgbase=python-cram
+pkgname=('python-cram' 'python2-cram')
+pkgver=0.7
+pkgrel=1
+pkgdesc='Functional tests for command line applications'
+arch=('any')
+url='https://bitheap.org/cram/'
+license=('GPL')
+makedepends=('python' 'python2' 'git')
+source=("https://bitheap.org/cram/cram-$pkgver.tar.gz")
+md5sums=('2ea37ada5190526b9bcaac5e4099221c')
+
+prepare() {
+  cp -a cram-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/cram-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/cram-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/cram-$pkgver
+  PYTHONPATH="$PWD/build/lib:$PYTHONPATH" python scripts/cram tests
+
+  cd "$srcdir"/cram-$pkgver-py2
+  PYTHONPATH="$PWD/build/lib:$PYTHONPATH" python2 scripts/cram tests
+}
+
+package_python-cram() {
+  depends=('python')
+
+  cd cram-$pkgver
+  python setup.py install --root="$pkgdir" -O1
+}
+
+package_python2-cram() {
+  depends=('python2')
+
+  cd cram-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" -O1
+
+  mv "$pkgdir"/usr/bin/cram{,2}
+}


Property changes on: python-cram/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property