[arch-commits] Commit in python-snakefood/repos (community-any community-any/PKGBUILD)

[Felix Yan]

    Date: Wednesday, December 14, 2016 @ 07:07:19
  Author: felixonmars
Revision: 199297

archrelease: copy trunk to community-any

Added:
  python-snakefood/repos/community-any/
  python-snakefood/repos/community-any/PKGBUILD
    (from rev 199296, python-snakefood/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: python-snakefood/repos/community-any/PKGBUILD (from rev 199296, python-snakefood/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2016-12-14 07:07:19 UTC (rev 199297)
@@ -0,0 +1,38 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Josip Ponjavic <josipponjavic at gmail dot com>
+# Contributor: Xu Fasheng <fasheng.xu[AT]gmail.com>
+
+pkgbase=python-snakefood
+pkgname=python2-snakefood
+pkgver=1.4.0.20160605
+_revision=6d55510bd30bf731ef9b4de5242733d12a478295
+pkgrel=1
+pkgdesc='Dependency Graphing for Python'
+arch=('any')
+url="http://furius.ca/snakefood"
+license=('GPL')
+depends=('python2-six')
+makedepends=('mercurial')
+checkdepends=('python2-pytest')
+source=("hg+https://bitbucket.org/blais/snakefood#revision=$_revision")
+sha256sums=('SKIP')
+
+prepare() {
+  sed -i 's|/usr/bin/env python|/usr/bin/env python2|' snakefood/bin/*
+}
+
+build() {
+  cd snakefood
+  python2 setup.py build
+}
+
+check() {
+  cd snakefood
+  PYTHONPATH="$PWD/build/lib:$PYTHONPATH" py.test2 || warning "Tests are broken"
+}
+
+package_python2-snakefood() {
+  cd snakefood
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}