[arch-commits] Commit in python-django-modeltranslation (3 files)

[Maxime Gauduin]

    Date: Wednesday, December 14, 2016 @ 13:57:02
  Author: alucryd
Revision: 199411

archrelease: copy trunk to community-any

Added:
  python-django-modeltranslation/repos/
  python-django-modeltranslation/repos/community-any/
  python-django-modeltranslation/repos/community-any/PKGBUILD
    (from rev 199410, python-django-modeltranslation/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: python-django-modeltranslation/repos/community-any/PKGBUILD (from rev 199410, python-django-modeltranslation/trunk/PKGBUILD)
===================================================================
--- repos/community-any/PKGBUILD	                        (rev 0)
+++ repos/community-any/PKGBUILD	2016-12-14 13:57:02 UTC (rev 199411)
@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgbase=python-django-modeltranslation
+pkgname=('python-django-modeltranslation' 'python2-django-modeltranslation')
+pkgver=0.12
+pkgrel=1
+pkgdesc='Translates Django models using a registration approach'
+arch=('any')
+url='https://github.com/deschler/django-modeltranslation'
+license=('BSD')
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("django-modeltranslation-${pkgver}.tar.gz::https://github.com/deschler/django-modeltranslation/archive/${pkgver}.tar.gz")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -r {,python-}django-modeltranslation-${pkgver}
+  mv {,python2-}django-modeltranslation-${pkgver}
+}
+
+build() {
+  for py in python{,2}; do
+    pushd ${py}-django-modeltranslation-${pkgver}
+    ${py} setup.py build
+    popd
+  done
+}
+
+package_python-django-modeltranslation() {
+  depends=('python-django')
+
+  cd python-django-modeltranslation-${pkgver}
+
+  python setup.py install --root="${pkgdir}" --optimize='1'
+  install -Dm 644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/python-django-modeltranslation/
+}
+
+package_python2-django-modeltranslation() {
+  depends=('python2-django')
+
+  cd python2-django-modeltranslation-${pkgver}
+
+  python2 setup.py install --root="${pkgdir}" --optimize='1'
+  install -Dm 644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/python2-django-modeltranslation/
+}
+
+# vim: ts=2 sw=2 et: