[arch-commits] Commit in (4 files)
Felix Yan
felixonmars at archlinux.org
Fri Dec 16 10:05:41 UTC 2016
Date: Friday, December 16, 2016 @ 10:05:41
Author: felixonmars
Revision: 199852
addpkg: deepin-cogl 1.22.3-1
Added:
deepin-cogl/
deepin-cogl/repos/
deepin-cogl/trunk/
deepin-cogl/trunk/PKGBUILD
----------+
PKGBUILD | 43 +++++++++++++++++++++++++++++++++++++++++++
1 file changed, 43 insertions(+)
Added: deepin-cogl/trunk/PKGBUILD
===================================================================
--- deepin-cogl/trunk/PKGBUILD (rev 0)
+++ deepin-cogl/trunk/PKGBUILD 2016-12-16 10:05:41 UTC (rev 199852)
@@ -0,0 +1,43 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=deepin-cogl
+pkgver=1.22.3
+pkgrel=1
+pkgdesc="An object oriented GL/GLES Abstraction/Utility Layer for Deepin"
+arch=('i686' 'x86_64')
+url="https://github.com/linuxdeepin/deepin-cogl"
+license=('GPL2')
+depends=('mesa' 'libdrm' 'libxext' 'libxdamage' 'libxcomposite' 'gdk-pixbuf2' 'pango' 'libxrandr')
+makedepends=('gobject-introspection' 'git' 'gtk-doc')
+provides=("cogl=$pkgver")
+conflicts=("cogl")
+options=(!emptydirs)
+source=("git+https://github.com/linuxdeepin/deepin-cogl.git#tag=$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+ cd $pkgname
+
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd $pkgname
+ ./configure --prefix=/usr \
+ --enable-gles{1,2} \
+ --enable-{kms,wayland}-egl-platform \
+ --enable-wayland-egl-server
+
+ # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+ make -j1
+}
+
+package() {
+ cd $pkgname
+ make DESTDIR="$pkgdir" install
+}
+
+# vim:set ts=2 sw=2 et:
Property changes on: deepin-cogl/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list