[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, December 21, 2016 @ 03:10:29
  Author: felixonmars
Revision: 200538

addpkg: python-zope-annotation 4.4.1-1

Added:
  python-zope-annotation/
  python-zope-annotation/repos/
  python-zope-annotation/trunk/
  python-zope-annotation/trunk/PKGBUILD

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Added: python-zope-annotation/trunk/PKGBUILD
===================================================================
--- python-zope-annotation/trunk/PKGBUILD	                        (rev 0)
+++ python-zope-annotation/trunk/PKGBUILD	2016-12-21 03:10:29 UTC (rev 200538)
@@ -0,0 +1,56 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=('python-zope-annotation' 'python2-zope-annotation')
+pkgver=4.4.1
+pkgrel=1
+pkgdesc="Object annotation mechanism"
+arch=('any')
+url="https://github.com/zopefoundation/zope.annotation"
+license=('ZPL')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-zope-interface'
+             'python2-zope-interface' 'python-zope-component' 'python2-zope-component'
+             'python-zope-location' 'python2-zope-location' 'python-zope-proxy' 'python2-zope-proxy'
+             'git')
+checkdepends=('python-nose' 'python2-nose' 'python-zope-configuration' 'python2-zope-configuration'
+              'python-zope-testing' 'python2-zope-testing')
+source=("git+https://github.com/zopefoundation/zope.annotation.git#tag=$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -a zope.annotation{,-py2}
+}
+
+build() {
+  cd "$srcdir"/zope.annotation
+  python setup.py build
+
+  cd "$srcdir"/zope.annotation-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/zope.annotation
+  nosetests3
+
+  cd "$srcdir"/zope.annotation-py2
+  nosetests2
+}
+
+package_python-zope-annotation() {
+  depends=('python-setuptools' 'python-zope-interface' 'python-zope-component'
+           'python-zope-location' 'python-zope-proxy')
+
+  cd "$srcdir/zope.annotation"
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-zope-annotation() {
+  depends=('python2-setuptools' 'python2-zope-interface' 'python2-zope-component'
+           'python2-zope-location' 'python2-zope-proxy')
+
+  cd "$srcdir/zope.annotation-py2"
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et:


Property changes on: python-zope-annotation/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property