[arch-commits] Commit in python-pyparsing/repos (staging-any staging-any/PKGBUILD)
Felix Yan
felixonmars at archlinux.org
Sat Dec 24 09:47:06 UTC 2016
Date: Saturday, December 24, 2016 @ 09:47:05
Author: felixonmars
Revision: 284557
archrelease: copy trunk to staging-any
Added:
python-pyparsing/repos/staging-any/
python-pyparsing/repos/staging-any/PKGBUILD
(from rev 284556, python-pyparsing/trunk/PKGBUILD)
----------+
PKGBUILD | 64 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 64 insertions(+)
Copied: python-pyparsing/repos/staging-any/PKGBUILD (from rev 284556, python-pyparsing/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD (rev 0)
+++ staging-any/PKGBUILD 2016-12-24 09:47:05 UTC (rev 284557)
@@ -0,0 +1,64 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Alexander F Rødseth <xyproto at archlinux.org>
+# Contributor: Chris Brannon <cmbrannon79 at gmail.com>
+# Contributor: Geoffroy Carrier <geoffroy.carrier at aur.archlinux.org>
+# Contributor: Arvid Ephraim Picciani <aep at exys.org>
+# Contributor: Michael Krauss <hippodriver at gmx.net>
+
+pkgname=python-pyparsing
+pkgname=('python-pyparsing' 'python2-pyparsing')
+pkgver=2.1.10
+pkgrel=2
+pkgdesc='General parsing module for Python'
+arch=('any')
+url='http://pyparsing.wikispaces.com/'
+makedepends=('python-setuptools' 'python2-setuptools' 'subversion')
+license=('MIT')
+source=("svn://svn.code.sf.net/p/pyparsing/code/tags/pyparsing_$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+ cp -a pyparsing_$pkgver{,-py2}
+
+ # :/
+ sed -i '1i#coding=utf-8' pyparsing_$pkgver-py2/src/unitTests.py
+}
+
+build() {
+ cd "$srcdir"/pyparsing_$pkgver/src
+ python setup.py build
+
+ cd "$srcdir"/pyparsing_$pkgver-py2/src
+ python2 setup.py build
+}
+
+check() {
+ export LC_CTYPE=en_US.UTF-8
+
+ cd "$srcdir"/pyparsing_$pkgver/src
+ python unitTests.py
+
+ cd "$srcdir"/pyparsing_$pkgver-py2/src
+ python2 unitTests.py
+}
+
+package_python-pyparsing() {
+ depends=('python')
+
+ cd pyparsing_$pkgver/src
+
+ python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
+ install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-pyparsing() {
+ depends=('python2')
+
+ cd pyparsing_$pkgver-py2/src
+
+ python2 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
+ install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list