[arch-commits] Commit in python-py/repos (2 files)

[Felix Yan]

    Date: Saturday, December 24, 2016 @ 10:21:51
  Author: felixonmars
Revision: 201318

archrelease: copy trunk to community-staging-any

Added:
  python-py/repos/community-staging-any/
  python-py/repos/community-staging-any/PKGBUILD
    (from rev 201317, python-py/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: python-py/repos/community-staging-any/PKGBUILD (from rev 201317, python-py/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-24 10:21:51 UTC (rev 201318)
@@ -0,0 +1,58 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Sebastian Wiesner <lunaryorn googlemail com>
+# Contributor: Igor Ramos Tiburcio <irtigor at yahoo.com.br>
+# Contributor: Wieland Hoffmann <themineo+aur at gmail.com>
+# Contributor: Hervé Cauwelier <herve ¤ oursours.net>
+# Contributor: Felix Kaiser <felix.kaiser at fxkr.net>
+
+pkgbase=python-py
+pkgname=('python-py' 'python2-py')
+pkgver=1.4.32
+pkgrel=2
+pkgdesc="library with cross-python path, ini-parsing, io, code, log facilities"
+arch=('any')
+license=('MIT')
+url="http://pylib.readthedocs.org/en/latest/"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest' 'python2-pytest')
+source=("git+https://github.com/pytest-dev/py.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a py{,-py2}
+}
+
+build() {
+  cd "$srcdir"/py
+  python setup.py build
+
+  cd "$srcdir"/py-py2
+  python2 setup.py build
+}
+
+check() {
+  export LC_CTYPE=en_US.UTF-8
+
+  cd "$srcdir"/py
+  PYTHONPATH="$PWD/build/lib:$PYTHONPATH" py.test
+
+  cd "$srcdir"/py-py2
+  PYTHONPATH="$PWD/build/lib:$PYTHONPATH" py.test2
+}
+
+package_python-py() {
+  depends=('python')
+
+  cd py
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-py() {
+  depends=('python2')
+
+  cd py-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}