[arch-commits] Commit in python-zope-exceptions/repos (2 files)

[Felix Yan]

    Date: Saturday, December 24, 2016 @ 11:05:18
  Author: felixonmars
Revision: 201377

archrelease: copy trunk to community-staging-any

Added:
  python-zope-exceptions/repos/community-staging-any/
  python-zope-exceptions/repos/community-staging-any/PKGBUILD
    (from rev 201376, python-zope-exceptions/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: python-zope-exceptions/repos/community-staging-any/PKGBUILD (from rev 201376, python-zope-exceptions/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-24 11:05:18 UTC (rev 201377)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=('python-zope-exceptions' 'python2-zope-exceptions')
+pkgver=4.0.8
+pkgrel=2
+pkgdesc="Generic exceptions and implementations for Zope"
+arch=('any')
+url="https://github.com/zopefoundation/zope.exceptions"
+license=('ZPL')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-zope-interface'
+             'python2-zope-interface' 'git')
+checkdepends=('python-nose' 'python2-nose')
+source=("git+https://github.com/zopefoundation/zope.exceptions.git#tag=$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -a zope.exceptions{,-py2}
+}
+
+build() {
+  cd "$srcdir/zope.exceptions"
+  python setup.py build
+
+  cd "$srcdir/zope.exceptions-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/zope.exceptions"
+  nosetests3
+
+  cd "$srcdir/zope.exceptions-py2"
+  nosetests2
+}
+
+package_python-zope-exceptions() {
+  depends=('python-setuptools' 'python-zope-interface')
+
+  cd "$srcdir/zope.exceptions"
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-zope-exceptions() {
+  depends=('python2-setuptools' 'python2-zope-interface')
+
+  cd "$srcdir/zope.exceptions-py2"
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et: