[arch-commits] Commit in python-ukpostcodeparser/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sat Dec 24 16:34:04 UTC 2016


    Date: Saturday, December 24, 2016 @ 16:34:03
  Author: felixonmars
Revision: 201561

archrelease: copy trunk to community-staging-any

Added:
  python-ukpostcodeparser/repos/community-staging-any/
  python-ukpostcodeparser/repos/community-staging-any/PKGBUILD
    (from rev 201560, python-ukpostcodeparser/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: python-ukpostcodeparser/repos/community-staging-any/PKGBUILD (from rev 201560, python-ukpostcodeparser/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-24 16:34:03 UTC (rev 201561)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-ukpostcodeparser
+pkgname=('python-ukpostcodeparser' 'python2-ukpostcodeparser')
+pkgver=1.1.0
+_commit=4040f2cdbf884e41a336271a0d654e785953b44b
+pkgrel=2
+pkgdesc="UK Postcode parser"
+arch=('any')
+license=('MIT')
+url="https://github.com/hamstah/ukpostcodeparser"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+source=("git+https://github.com/hamstah/ukpostcodeparser.git#commit=$_commit")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a ukpostcodeparser{,-py2}
+}
+
+build() {
+  cd "$srcdir"/ukpostcodeparser
+  python setup.py build
+
+  cd "$srcdir"/ukpostcodeparser-py2
+  python2 setup.py build
+}
+
+check() {
+  # Expected failure: https://github.com/hamstah/ukpostcodeparser/issues/5
+
+  cd "$srcdir"/ukpostcodeparser
+  python -m unittest discover -s ukpostcodeparser/test -p '*.py' || warning "Tests failed"
+
+  cd "$srcdir"/ukpostcodeparser-py2
+  python2 -m unittest discover -s ukpostcodeparser/test -p '*.py' || warning "Tests failed"
+}
+
+package_python-ukpostcodeparser() {
+  depends=('python')
+
+  cd ukpostcodeparser
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-ukpostcodeparser() {
+  depends=('python2')
+
+  cd ukpostcodeparser-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}
+



More information about the arch-commits mailing list