[arch-commits] Commit in python-bottle/repos (2 files)

[Felix Yan]

    Date: Saturday, December 24, 2016 @ 16:39:47
  Author: felixonmars
Revision: 201566

archrelease: copy trunk to community-staging-any

Added:
  python-bottle/repos/community-staging-any/
  python-bottle/repos/community-staging-any/PKGBUILD
    (from rev 201565, python-bottle/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: python-bottle/repos/community-staging-any/PKGBUILD (from rev 201565, python-bottle/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-24 16:39:47 UTC (rev 201566)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Richard Murri <admin at richardmurri.com>
+# Contributor: Farhad Shahbazi <farhad at enthusiasm.cc>
+# Contributor: Felix Kaiser <felix.kaiser at fxkr.net>
+
+pkgbase=python-bottle
+pkgname=("python-bottle" "python2-bottle")
+pkgver=0.12.11
+pkgrel=2
+pkgdesc="A fast and simple micro-framework for small web-applications"
+arch=(any)
+url="http://bottlepy.org"
+license=('MIT')
+options=(!emptydirs)
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-mako' 'python2-mako' 'python-jinja' 'python2-jinja' 'python-cherrypy'
+              'python2-cherrypy' 'python-twisted' 'python2-twisted' 'python-tornado'
+              'python2-tornado' 'python-paste' 'python2-paste' 'python-gevent' 'python2-gevent'
+              'python-eventlet' 'python2-eventlet')
+source=("git+https://github.com/defnull/bottle.git#tag=${pkgver}")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a bottle{,-py2}
+  sed -i "1s/python/python2/" bottle-py2/bottle.py
+}
+
+check() {
+  cd "$srcdir/"bottle
+  # https://github.com/bottlepy/bottle/issues/791
+  python test/testall.py || warning 'Tests failed'
+
+  cd "$srcdir/"bottle-py2
+  python2 test/testall.py
+}
+
+package_python-bottle() {
+  depends=('python')
+
+  cd bottle
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-bottle() {
+  depends=('python2')
+
+  cd bottle-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+  # deal with conflict with python-bottle's /usr/bin/bottle.py
+  mv "$pkgdir"/usr/bin/bottle.py{,2}
+}