[arch-commits] Commit in python-pytest-cov/repos (2 files)

[Felix Yan]

    Date: Saturday, December 24, 2016 @ 17:17:05
  Author: felixonmars
Revision: 201609

archrelease: copy trunk to community-staging-any

Added:
  python-pytest-cov/repos/community-staging-any/
  python-pytest-cov/repos/community-staging-any/PKGBUILD
    (from rev 201608, python-pytest-cov/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: python-pytest-cov/repos/community-staging-any/PKGBUILD (from rev 201608, python-pytest-cov/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-24 17:17:05 UTC (rev 201609)
@@ -0,0 +1,59 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Sebastien LEDUC <sebastien at sleduc.fr>
+# Contributor: Andrey Mikhaylenko <neithere at gmail dot com>
+
+pkgbase=python-pytest-cov
+pkgname=('python-pytest-cov' 'python2-pytest-cov')
+pkgver=2.4.0
+pkgrel=2
+pkgdesc='py.test plugin for coverage reporting with support for both centralised and distributed testing, including subprocesses and multiprocessing'
+arch=('any')
+license=('MIT')
+url='https://github.com/schlamar/pytest-cov'
+makedepends=('python-coverage' 'python2-coverage' 'python-setuptools' 'python2-setuptools'
+             'python-pytest' 'python2-pytest' 'git')
+checkdepends=('python-virtualenv' 'python2-virtualenv' 'python-process-tests' 'python2-process-tests'
+              'python-pytest-cache' 'python2-pytest-cache' 'python-pytest-xdist' 'python2-pytest-xdist'
+              'python-pytest-capturelog' 'python2-pytest-capturelog')
+source=("git+https://github.com/pytest-dev/pytest-cov.git#tag=v$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a pytest-cov{,-py2}
+}
+
+build() {
+  cd "$srcdir"/pytest-cov
+  python setup.py build
+
+  cd "$srcdir"/pytest-cov-py2
+  python2 setup.py build
+}
+
+check() {
+  # Hack entry points by installing it
+
+  cd "$srcdir"/pytest-cov
+  python setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python3.5/site-packages:$PYTHONPATH:$PWD/tests" py.test || warning "Tests failed"
+
+  cd "$srcdir"/pytest-cov-py2
+  python2 setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python2.7/site-packages:$PYTHONPATH:$PWD/tests" py.test2 || warning "Tests failed"
+}
+
+package_python-pytest-cov() {
+  depends=('python-pytest' 'python-coverage')
+
+  cd pytest-cov
+  python setup.py install --root="$pkgdir"/ --optimize=1
+}
+
+package_python2-pytest-cov() {
+  depends=('python2-pytest' 'python2-coverage')
+
+  cd pytest-cov-py2
+  python2 setup.py install --root="$pkgdir"/ --optimize=1
+}
+# vim:set ts=2 sw=2 et: