[arch-commits] Commit in python-isort/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Sat Dec 24 17:22:56 UTC 2016
Date: Saturday, December 24, 2016 @ 17:22:55
Author: felixonmars
Revision: 284652
archrelease: copy trunk to community-staging-any
Added:
python-isort/repos/community-staging-any/
python-isort/repos/community-staging-any/PKGBUILD
(from rev 284651, python-isort/trunk/PKGBUILD)
----------+
PKGBUILD | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 54 insertions(+)
Copied: python-isort/repos/community-staging-any/PKGBUILD (from rev 284651, python-isort/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD (rev 0)
+++ community-staging-any/PKGBUILD 2016-12-24 17:22:55 UTC (rev 284652)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Yaron de Leeuw <me at jarondl.net>
+
+pkgbase=python-isort
+pkgname=('python-isort' 'python2-isort')
+pkgver=4.2.5
+pkgrel=2
+pkgdesc="A Python utility / library to sort Python imports."
+arch=('any')
+url="https://github.com/timothycrosley/isort"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest' 'python2-pytest' 'python-mock' 'python2-mock')
+source=("git+https://github.com/timothycrosley/isort.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+ cp -a isort{,-py2}
+}
+
+build() {
+ cd "$srcdir"/isort
+ python setup.py build
+
+ cd "$srcdir"/isort-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/isort
+ python setup.py test
+
+ cd "$srcdir"/isort-py2
+ python2 setup.py test
+}
+
+package_python-isort() {
+ depends=('python-setuptools')
+
+ cd isort
+ python setup.py install --root="$pkgdir/" --optimize=1
+ install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-isort() {
+ depends=('python2-setuptools')
+
+ cd isort-py2
+ python2 setup.py install --root="$pkgdir/" --optimize=1
+ install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+ mv "$pkgdir"/usr/bin/isort{,2}
+}
More information about the arch-commits
mailing list