[arch-commits] Commit in python-keystoneauth1/repos (2 files)

[Felix Yan]

    Date: Saturday, December 24, 2016 @ 17:31:51
  Author: felixonmars
Revision: 201630

archrelease: copy trunk to community-staging-any

Added:
  python-keystoneauth1/repos/community-staging-any/
  python-keystoneauth1/repos/community-staging-any/PKGBUILD
    (from rev 201627, python-keystoneauth1/trunk/PKGBUILD)

----------+
 PKGBUILD |   75 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 75 insertions(+)

Copied: python-keystoneauth1/repos/community-staging-any/PKGBUILD (from rev 201627, python-keystoneauth1/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-24 17:31:51 UTC (rev 201630)
@@ -0,0 +1,75 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
+
+pkgbase=python-keystoneauth1
+pkgname=(python-keystoneauth1 python2-keystoneauth1)
+pkgver=2.16.0
+pkgrel=2
+pkgdesc="Authentication Library for OpenStack Identity"
+arch=('any')
+url="http://docs.openstack.org/developer/keystoneauth"
+license=('Apache')
+makedepends=('git' 'python-setuptools' 'python2-setuptools' 'python-pbr' 'python2-pbr'
+             'python-iso8601' 'python2-iso8601' 'python-positional' 'python2-positional'
+             'python-requests' 'python2-requests' 'python-stevedore' 'python2-stevedore')
+checkdepends=('python-testrepository' 'python2-testrepository' 'python-requests-mock'
+              'python2-requests-mock' 'python-testscenarios' 'python2-testscenarios'
+              'python-mock' 'python2-mock' 'python-lxml' 'python2-lxml' 'python-oslo-config'
+              'python2-oslo-config' 'python-betamax' 'python2-betamax' 'python-oslotest'
+              'python2-oslotest' 'python-oslo-utils' 'python2-oslo-utils' 'python-requests-kerberos'
+              'python2-requests-kerberos' 'python-oauthlib' 'python2-oauthlib' 'python-pycodestyle'
+              'python2-pycodestyle')
+source=("git+https://git.openstack.org/openstack/keystoneauth#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  # Use pycodestyle
+  sed -i 's/pep8/pycodestyle/g' keystoneauth/keystoneauth1/tests/unit/test_hacking_checks.py
+
+  cp -a keystoneauth{,-py2}
+}
+
+build() {
+  cd "$srcdir"/keystoneauth
+  python setup.py build
+
+  cd "$srcdir"/keystoneauth-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/keystoneauth
+  python setup.py testr || warning "Tests failed"
+
+  cd "$srcdir"/keystoneauth-py2
+  PYTHON=python2 python2 setup.py testr
+}
+
+package_python-keystoneauth1() {
+  depends=('python-pbr' 'python-iso8601' 'python-stevedore' 'python-positional' 'python-requests')
+  optdepends=('python-requests-kerberos: for kerberos support'
+              'python-lxml: for saml2 support'
+              'python-oauthlib: for oauth1 support'
+              'python-betamax: for betamax support'
+              'python-fixtures: for betamax support'
+              'python-mock: for betamax support')
+
+  cd "$srcdir"/keystoneauth
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-keystoneauth1() {
+  depends=('python2-pbr' 'python2-iso8601' 'python2-stevedore' 'python2-positional' 'python2-requests')
+  optdepends=('python2-requests-kerberos: for kerberos support'
+              'python2-lxml: for saml2 support'
+              'python2-oauthlib: for oauth1 support'
+              'python2-betamax: for betamax support'
+              'python2-fixtures: for betamax support'
+              'python2-mock: for betamax support')
+
+  cd "$srcdir"/keystoneauth-py2
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et: