[arch-commits] Commit in python-hyperframe/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Sat Dec 24 17:36:06 UTC 2016
Date: Saturday, December 24, 2016 @ 17:36:04
Author: felixonmars
Revision: 201651
archrelease: copy trunk to community-staging-any
Added:
python-hyperframe/repos/community-staging-any/
python-hyperframe/repos/community-staging-any/PKGBUILD
(from rev 201650, python-hyperframe/trunk/PKGBUILD)
----------+
PKGBUILD | 51 +++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 51 insertions(+)
Copied: python-hyperframe/repos/community-staging-any/PKGBUILD (from rev 201650, python-hyperframe/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD (rev 0)
+++ community-staging-any/PKGBUILD 2016-12-24 17:36:04 UTC (rev 201651)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-hyperframe
+pkgname=('python-hyperframe' 'python2-hyperframe')
+pkgver=4.0.1
+pkgrel=2
+pkgdesc="HTTP/2 framing layer for Python"
+arch=('any')
+license=('MIT')
+url="http://hyper.rtfd.org"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("git+https://github.com/python-hyper/hyperframe.git#tag=v$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+ cp -a hyperframe{,-py2}
+}
+
+build() {
+ cd "$srcdir"/hyperframe
+ python setup.py build
+
+ cd "$srcdir"/hyperframe-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/hyperframe
+ python setup.py ptr
+
+ cd "$srcdir"/hyperframe-py2
+ python2 setup.py ptr
+}
+
+package_python-hyperframe() {
+ depends=('python')
+
+ cd hyperframe
+ python setup.py install --root="$pkgdir" --optimize=1
+ install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-hyperframe() {
+ depends=('python2')
+
+ cd hyperframe-py2
+ python2 setup.py install --root="$pkgdir" --optimize=1
+ install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
More information about the arch-commits
mailing list