[arch-commits] Commit in python-oslo-serialization/repos (2 files)

[Felix Yan]

    Date: Saturday, December 24, 2016 @ 17:47:14
  Author: felixonmars
Revision: 201676

archrelease: copy trunk to community-staging-any

Added:
  python-oslo-serialization/repos/community-staging-any/
  python-oslo-serialization/repos/community-staging-any/PKGBUILD
    (from rev 201675, python-oslo-serialization/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: python-oslo-serialization/repos/community-staging-any/PKGBUILD (from rev 201675, python-oslo-serialization/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-24 17:47:14 UTC (rev 201676)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-oslo-serialization
+pkgname=(python-oslo-serialization python2-oslo-serialization)
+pkgver=2.15.0
+pkgrel=2
+pkgdesc="Oslo Serialization library"
+arch=('any')
+url="http://docs.openstack.org/developer/oslo.serialization"
+license=('Apache')
+makedepends=('git' 'python-setuptools' 'python2-setuptools' 'python-pbr' 'python2-pbr'
+             'python-babel' 'python2-babel' 'python-msgpack' 'python2-msgpack'
+             'python-oslo-utils' 'python2-oslo-utils' 'python-pytz' 'python2-pytz')
+checkdepends=('python-oslotest' 'python2-oslotest' 'python2-ipaddress')
+source=("git+https://git.openstack.org/openstack/oslo.serialization#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a oslo.serialization{,-py2}
+}
+
+build() {
+  cd "$srcdir"/oslo.serialization
+  python setup.py build
+
+  cd "$srcdir"/oslo.serialization-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/oslo.serialization
+  python setup.py testr
+
+  cd "$srcdir"/oslo.serialization-py2
+  PYTHON=python2 python2 setup.py testr
+}
+
+package_python-oslo-serialization() {
+  depends=('python-six' 'python-pbr' 'python-babel' 'python-msgpack' 'python-oslo-utils'
+           'python-pytz')
+
+  cd "$srcdir"/oslo.serialization
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-oslo-serialization() {
+  depends=('python2-six' 'python2-pbr' 'python2-babel' 'python2-msgpack' 'python2-oslo-utils'
+           'python2-pytz')
+
+  cd "$srcdir"/oslo.serialization-py2
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et: