[arch-commits] Commit in autopep8/repos (2 files)

[Evangelos Foutras]

    Date: Saturday, December 24, 2016 @ 18:04:03
  Author: foutrelis
Revision: 201741

archrelease: copy trunk to community-staging-any

Added:
  autopep8/repos/community-staging-any/
  autopep8/repos/community-staging-any/PKGBUILD
    (from rev 201740, autopep8/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: autopep8/repos/community-staging-any/PKGBUILD (from rev 201740, autopep8/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-24 18:04:03 UTC (rev 201741)
@@ -0,0 +1,60 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Ismael Carnales <icarnales at gmail dot com>
+# Contributor: Sergey Mastykov <smastykov[at]gmail[dot]com>
+
+pkgbase=autopep8
+pkgname=(autopep8 python2-autopep8)
+pkgver=2.0a1
+_commit=152dcbcba066848c3c6dd333821f66a05ab60b95
+pkgrel=2
+pkgdesc="A tool that automatically formats Python code to conform to the PEP 8 style guide"
+arch=('any')
+url="http://github.com/hhatto/autopep8"
+license=('MIT')
+makedepends=('python-pycodestyle' 'python2-pycodestyle' 'git')
+source=("git+https://github.com/hhatto/autopep8.git#commit=$_commit")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -a autopep8{,-py2}
+}
+
+build() {
+  cd "$srcdir"/autopep8
+  python setup.py build
+
+  cd "$srcdir"/autopep8-py2
+  python2 setup.py build
+}
+
+check() {
+  export LC_CTYPE=en_US.UTF-8
+
+  cd "$srcdir"/autopep8
+  python setup.py test
+
+  cd "$srcdir"/autopep8-py2
+  python2 setup.py test
+}
+
+package_autopep8() {
+  depends=('python-pycodestyle')
+
+  cd autopep8
+  python3 setup.py install -O1 --prefix=/usr --root="$pkgdir/"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-autopep8() {
+  depends=('python2-pycodestyle')
+
+  cd autopep8-py2
+  python2 setup.py install -O1 --prefix=/usr --root="$pkgdir/"
+  mv "$pkgdir/usr/bin/autopep8" "$pkgdir/usr/bin/autopep8-python2"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et: