[arch-commits] Commit in flake8/repos (2 files)
Evangelos Foutras
foutrelis at archlinux.org
Sat Dec 24 18:04:37 UTC 2016
Date: Saturday, December 24, 2016 @ 18:04:36
Author: foutrelis
Revision: 201744
archrelease: copy trunk to community-staging-any
Added:
flake8/repos/community-staging-any/
flake8/repos/community-staging-any/PKGBUILD
(from rev 201743, flake8/trunk/PKGBUILD)
----------+
PKGBUILD | 69 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 69 insertions(+)
Copied: flake8/repos/community-staging-any/PKGBUILD (from rev 201743, flake8/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD (rev 0)
+++ community-staging-any/PKGBUILD 2016-12-24 18:04:36 UTC (rev 201744)
@@ -0,0 +1,69 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Karol "Kenji Takahashi" Woźniak <kenji.sx>
+# Contributor: spider-mario <spidermario at free.fr>
+# Contributor: Allen Li <darkfeline at abagofapples.com>
+
+pkgbase=flake8
+pkgname=(flake8 python2-flake8)
+pkgver=3.2.1
+pkgrel=2
+epoch=1
+pkgdesc="The modular source code checker: pep8, pyflakes and co"
+arch=('any')
+url="http://bitbucket.org/tarek/flake8"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-pyflakes' 'python2-pyflakes'
+ 'python-pycodestyle' 'python2-pycodestyle' 'python-mccabe' 'python2-mccabe'
+ 'python2-enum34' 'python2-configparser' 'python-pytest-runner' 'python2-pytest-runner'
+ 'git')
+checkdepends=('python-mock' 'python2-mock')
+source=("git+https://gitlab.com/pycqa/flake8.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+ sed -i -e 's/, *< *[0-9=.]*//' flake8/setup.py
+ cp -a flake8{,-py2}
+}
+
+build() {
+ cd "$srcdir"/flake8
+ python setup.py build
+
+ cd "$srcdir"/flake8-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/flake8
+ python setup.py ptr
+
+ cd "$srcdir"/flake8-py2
+ python2 setup.py ptr
+}
+
+package_flake8() {
+ depends=('python-pyflakes' 'python-mccabe' 'python-pycodestyle')
+ provides=('flake8-python3')
+ replaces=('flake8-python3')
+ conflicts=('flake8-python3')
+
+ cd "$srcdir"/flake8
+ python setup.py install --root="$pkgdir" --prefix=/usr --optimize=1
+ install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-flake8() {
+ depends=('python2-pyflakes' 'python2-mccabe' 'python2-pycodestyle' 'python2-enum34'
+ 'python2-configparser')
+ provides=('flake8-python2')
+ replaces=('flake8-python2')
+ conflicts=('flake8-python2')
+
+ cd "$srcdir"/flake8-py2
+ python2 setup.py install --root="$pkgdir" --prefix=/usr --optimize=1
+ mv "$pkgdir"/usr/bin/flake8{,-python2}
+ install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list