[arch-commits] Commit in python-cliff/repos (2 files)
Evangelos Foutras
foutrelis at archlinux.org
Sat Dec 24 18:13:26 UTC 2016
Date: Saturday, December 24, 2016 @ 18:13:25
Author: foutrelis
Revision: 201750
archrelease: copy trunk to community-staging-any
Added:
python-cliff/repos/community-staging-any/
python-cliff/repos/community-staging-any/PKGBUILD
(from rev 201749, python-cliff/trunk/PKGBUILD)
----------+
PKGBUILD | 59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 59 insertions(+)
Copied: python-cliff/repos/community-staging-any/PKGBUILD (from rev 201749, python-cliff/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD (rev 0)
+++ community-staging-any/PKGBUILD 2016-12-24 18:13:25 UTC (rev 201750)
@@ -0,0 +1,59 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
+
+pkgbase=python-cliff
+pkgname=(python-cliff python2-cliff)
+pkgver=2.3.0
+pkgrel=2
+pkgdesc="Command Line Interface Formulation Framework"
+arch=('any')
+url="http://docs.openstack.org/developer/cliff"
+license=('Apache')
+makedepends=('git' 'python-setuptools' 'python2-setuptools' 'python-pbr' 'python2-pbr'
+ 'python-cmd2' 'python2-cmd2' 'python-prettytable' 'python2-prettytable'
+ 'python-pyparsing' 'python2-pyparsing' 'python-stevedore'
+ 'python2-stevedore' 'python-unicodecsv' 'python2-unicodecsv' 'python-yaml'
+ 'python2-yaml')
+checkdepends=('python-nose' 'python2-nose' 'python-mock' 'python2-mock')
+options=('!emptydirs')
+source=("git+https://git.openstack.org/openstack/cliff#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+ cp -a cliff{,-py2}
+}
+
+build() {
+ cd "$srcdir"/cliff
+ python setup.py build
+
+ cd "$srcdir"/cliff-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/cliff
+ PYTHONPATH="$PWD/build/lib:$PYTHONPATH" nosetests3 -d
+
+ cd "$srcdir"/cliff-py2
+ PYTHONPATH="$PWD/build/lib:$PYTHONPATH" nosetests2 -d
+}
+
+package_python-cliff() {
+ depends=('python-six' 'python-pbr' 'python-cmd2' 'python-prettytable' 'python-pyparsing'
+ 'python-stevedore' 'python-unicodecsv' 'python-yaml')
+
+ cd "$srcdir"/cliff
+ python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-cliff() {
+ depends=('python2-six' 'python2-pbr' 'python2-cmd2' 'python2-prettytable' 'python2-pyparsing'
+ 'python2-stevedore' 'python2-unicodecsv' 'python2-yaml')
+
+ cd "$srcdir"/cliff-py2
+ python2 setup.py install --root="$pkgdir/" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list