[arch-commits] Commit in python-pytest-flake8/repos (2 files)

[Felix Yan]

    Date: Saturday, December 24, 2016 @ 18:19:45
  Author: felixonmars
Revision: 201754

archrelease: copy trunk to community-staging-any

Added:
  python-pytest-flake8/repos/community-staging-any/
  python-pytest-flake8/repos/community-staging-any/PKGBUILD
    (from rev 201753, python-pytest-flake8/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: python-pytest-flake8/repos/community-staging-any/PKGBUILD (from rev 201753, python-pytest-flake8/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-24 18:19:45 UTC (rev 201754)
@@ -0,0 +1,59 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-pytest-flake8
+pkgname=('python-pytest-flake8' 'python2-pytest-flake8')
+pkgver=0.8.1
+pkgrel=2
+pkgdesc='pytest plugin to check FLAKE8 requirements'
+arch=('any')
+license=('MIT')
+url='http://github.com/tholo/pytest-flake8'
+makedepends=('python-pytest' 'python2-pytest' 'flake8' 'python2-flake8' 'git')
+source=("git+https://github.com/tholo/pytest-flake8#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  # https://github.com/tholo/pytest-flake8/pull/14
+  sed -i 's/flake8-ignore = E128/flake8-ignore = E128 E501/' pytest-flake8/tox.ini
+
+  cp -a pytest-flake8{,-py2}
+}
+
+build() {
+  cd "$srcdir"/pytest-flake8
+  python setup.py build
+
+  cd "$srcdir"/pytest-flake8-py2
+  python2 setup.py build
+}
+
+check() {
+  # Hack entry points by installing it
+
+  cd "$srcdir"/pytest-flake8
+  python setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python3.6/site-packages:$PYTHONPATH" py.test
+
+  cd "$srcdir"/pytest-flake8-py2
+  python2 setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python2.7/site-packages:$PYTHONPATH" py.test2
+}
+
+package_python-pytest-flake8() {
+  depends=('python-pytest' 'flake8')
+
+  cd pytest-flake8
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-pytest-flake8() {
+  depends=('python2-pytest' 'python2-flake8')
+
+  cd pytest-flake8-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+# vim:set ts=2 sw=2 et: