[arch-commits] Commit in python-wsgiproxy2/repos (2 files)

[Felix Yan]

    Date: Sunday, December 25, 2016 @ 03:39:55
  Author: felixonmars
Revision: 201826

archrelease: copy trunk to community-staging-any

Added:
  python-wsgiproxy2/repos/community-staging-any/
  python-wsgiproxy2/repos/community-staging-any/PKGBUILD
    (from rev 201825, python-wsgiproxy2/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: python-wsgiproxy2/repos/community-staging-any/PKGBUILD (from rev 201825, python-wsgiproxy2/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-25 03:39:55 UTC (rev 201826)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-wsgiproxy2
+pkgname=('python-wsgiproxy2' 'python2-wsgiproxy2')
+pkgver=0.4.2
+pkgrel=2
+pkgdesc="A WSGI Proxy with various http client backends"
+arch=('any')
+license=('MIT')
+url="https://github.com/gawel/WSGIProxy2/"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-webob' 'python2-webob'
+             'python-six' 'python2-six' 'git')
+checkdepends=('python-nose' 'python2-nose' 'python-requests' 'python2-requests'
+              'python-webtest' 'python2-webtest' 'python-waitress' 'python2-waitress')
+source=("git+https://github.com/gawel/WSGIProxy2.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a WSGIProxy2{,-py2}
+}
+
+build() {
+  cd "$srcdir/WSGIProxy2"
+  python setup.py build
+
+  cd "$srcdir/WSGIProxy2-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/WSGIProxy2"
+  nosetests3
+
+  cd "$srcdir/WSGIProxy2-py2"
+  # We don't provide restkit (looks obsolete to me)
+  nosetests2 || warning "Tests failed"
+}
+
+package_python-wsgiproxy2() {
+  depends=('python-webob' 'python-six')
+
+  cd WSGIProxy2
+  python setup.py install --root="${pkgdir}" --optimize=1
+}
+
+package_python2-wsgiproxy2() {
+  depends=('python2-webob' 'python2-six')
+
+  cd WSGIProxy2-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+}