[arch-commits] Commit in python-hpack/repos (2 files)

[Felix Yan]

    Date: Sunday, December 25, 2016 @ 05:50:52
  Author: felixonmars
Revision: 201840

archrelease: copy trunk to community-staging-any

Added:
  python-hpack/repos/community-staging-any/
  python-hpack/repos/community-staging-any/PKGBUILD
    (from rev 201839, python-hpack/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: python-hpack/repos/community-staging-any/PKGBUILD (from rev 201839, python-hpack/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-25 05:50:52 UTC (rev 201840)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-hpack
+pkgname=(python-hpack python2-hpack)
+pkgver=2.3.0
+pkgrel=2
+pkgdesc="Pure-Python HPACK header compression"
+arch=('any')
+url="http://hyper.rtfd.org/"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-hypothesis' 'python2-hypothesis')
+source=("git+https://github.com/Lukasa/hpack.git#tag=v$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a hpack{,-py2}
+}
+
+build() {
+  cd "$srcdir"/hpack
+  python setup.py build
+
+  cd "$srcdir"/hpack-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/hpack
+  python setup.py ptr
+
+  cd "$srcdir"/hpack-py2
+  python2 setup.py ptr
+}
+
+package_python-hpack() {
+  depends=('python')
+
+  cd hpack
+  python setup.py install -O1 --root "$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-hpack() {
+  depends=('python2')
+
+  cd hpack-py2
+  python2 setup.py install -O1 --root "$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}