[arch-commits] Commit in python-case/repos (2 files)

[Felix Yan]

    Date: Sunday, December 25, 2016 @ 16:39:51
  Author: felixonmars
Revision: 201931

archrelease: copy trunk to community-staging-any

Added:
  python-case/repos/community-staging-any/
  python-case/repos/community-staging-any/PKGBUILD
    (from rev 201930, python-case/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: python-case/repos/community-staging-any/PKGBUILD (from rev 201930, python-case/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-25 16:39:51 UTC (rev 201931)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-case
+pkgname=('python-case' 'python2-case')
+pkgver=1.5.2
+_commit=d2eb04d9ef1ee2f1d3bca37cd9fb6b0ff8cc7405
+pkgrel=2
+pkgdesc="Python unittest Utilities"
+arch=('any')
+license=('BSD')
+url="https://github.com/celery/case"
+makedepends=('python-nose' 'python2-nose' 'python2-mock' 'python2-unittest2' 'git')
+checkdepends=('python-coverage' 'python2-coverage')
+source=("git+https://github.com/celery/case.git#commit=$_commit")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a case{,-py2}
+}
+
+build() {
+  cd "$srcdir"/case
+  python setup.py build
+
+  cd "$srcdir"/case-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/case
+  nosetests3
+
+  cd "$srcdir"/case-py2
+  nosetests2
+}
+
+package_python-case() {
+  depends=('python-nose')
+
+  cd case
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-case() {
+  depends=('python2-nose' 'python2-mock' 'python2-unittest2')
+
+  cd case-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}