[arch-commits] Commit in python-xpybutil/repos (2 files)

[Felix Yan]

    Date: Sunday, December 25, 2016 @ 16:42:50
  Author: felixonmars
Revision: 201938

archrelease: copy trunk to community-staging-any

Added:
  python-xpybutil/repos/community-staging-any/
  python-xpybutil/repos/community-staging-any/PKGBUILD
    (from rev 201936, python-xpybutil/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: python-xpybutil/repos/community-staging-any/PKGBUILD (from rev 201936, python-xpybutil/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-25 16:42:50 UTC (rev 201938)
@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-xpybutil
+pkgname=(python-xpybutil python2-xpybutil)
+pkgver=0.0.1.20151007
+_commit=570f225e09b0f0fb05cee27e6660c19b5d0ee6bb
+pkgrel=2
+pkgdesc="An incomplete xcb-util port plus some extras"
+arch=('any')
+url="https://github.com/BurntSushi/xpybutil"
+license=('custom:WTFPL')
+makedepends=('git' 'python-xcffib' 'python2-xcffib')
+source=("git+https://github.com/BurntSushi/xpybutil.git#commit=$_commit")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a xpybutil{,-py2}
+}
+
+build() {
+  cd "$srcdir/xpybutil"
+  python setup.py build
+
+  cd "$srcdir/xpybutil-py2"
+  python2 setup.py build
+}
+
+package_python-xpybutil() {
+  depends=('python-xcffib')
+
+  cd "${srcdir}/xpybutil"
+  python setup.py install --root="${pkgdir}/" --optimize=1
+
+  install -Dm664 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
+  mv "$pkgdir/usr/share/doc/"{,python-}xpybutil
+}
+
+package_python2-xpybutil() {
+  depends=('python2-xcffib')
+
+  cd "${srcdir}/xpybutil-py2"
+  python2 setup.py install --root="${pkgdir}/" --optimize=1
+
+  install -Dm664 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
+  mv "$pkgdir/usr/share/doc/"{,python2-}xpybutil
+}