[arch-commits] Commit in python-exam/repos (2 files)

[Bartłomiej Piotrowski]

    Date: Sunday, December 25, 2016 @ 16:48:18
  Author: bpiotrowski
Revision: 201965

archrelease: copy trunk to community-staging-any

Added:
  python-exam/repos/community-staging-any/
  python-exam/repos/community-staging-any/PKGBUILD
    (from rev 201964, python-exam/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: python-exam/repos/community-staging-any/PKGBUILD (from rev 201964, python-exam/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-25 16:48:18 UTC (rev 201965)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_pypiname=exam
+pkgbase=python-exam
+pkgname=('python-exam' 'python2-exam')
+pkgver=0.10.6
+pkgrel=2
+pkgdesc="Helpers for better testing"
+arch=('any')
+url="https://pypi.python.org/pypi/exam"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-mock' 'python2-mock' 'git')
+checkdepends=('python-nose' 'python2-nose')
+source=("git+https://github.com/Fluxx/exam.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a exam{,-py2}
+}
+
+build() {
+  cd "$srcdir/exam"
+  python setup.py build
+
+  cd "$srcdir/exam-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/exam"
+  python setup.py test
+
+  cd "$srcdir/exam-py2"
+  python2 setup.py test
+}
+
+package_python-exam() {
+  depends=('python-mock')
+
+  cd "$srcdir/$_pypiname"
+  python setup.py install --root="$pkgdir/" --optimize=1
+  install -Dm664 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-exam() {
+  depends=('python2-mock')
+
+  cd "$srcdir/$_pypiname-py2"
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+  install -Dm664 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et: