[arch-commits] Commit in python-cycler/repos (2 files)

[Felix Yan]

    Date: Sunday, December 25, 2016 @ 18:04:11
  Author: felixonmars
Revision: 202201

archrelease: copy trunk to community-staging-any

Added:
  python-cycler/repos/community-staging-any/
  python-cycler/repos/community-staging-any/PKGBUILD
    (from rev 202200, python-cycler/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: python-cycler/repos/community-staging-any/PKGBUILD (from rev 202200, python-cycler/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-25 18:04:11 UTC (rev 202201)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-cycler
+pkgname=('python-cycler' 'python2-cycler')
+pkgver=0.10.0
+pkgrel=2
+pkgdesc="Composable style cycles"
+arch=('any')
+license=('BSD')
+url="http://github.com/matplotlib/cycler"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-six' 'python2-six' 'git')
+checkdepends=('python-nose' 'python2-nose' 'python-coverage' 'python2-coverage')
+source=("git+https://github.com/matplotlib/cycler.git#tag=v$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a cycler{,-py2}
+}
+
+build() {
+  cd "$srcdir/cycler"
+  python setup.py build
+
+  cd "$srcdir/cycler-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/cycler"
+  python run_tests.py
+
+  cd "$srcdir/cycler-py2"
+  python2 run_tests.py
+}
+
+package_python-cycler() {
+  depends=('python-six')
+
+  cd cycler
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-cycler() {
+  depends=('python2-six')
+
+  cd cycler-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}