[arch-commits] Commit in python-braintree/repos (2 files)

[Bartłomiej Piotrowski]

    Date: Sunday, December 25, 2016 @ 18:04:59
  Author: bpiotrowski
Revision: 202205

archrelease: copy trunk to community-staging-any

Added:
  python-braintree/repos/community-staging-any/
  python-braintree/repos/community-staging-any/PKGBUILD
    (from rev 202204, python-braintree/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: python-braintree/repos/community-staging-any/PKGBUILD (from rev 202204, python-braintree/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-25 18:04:59 UTC (rev 202205)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-braintree
+pkgname=(python-braintree python2-braintree)
+pkgver=3.32.0
+pkgrel=2
+pkgdesc="Braintree Python Library"
+arch=('any')
+url="https://www.braintreepayments.com/docs/python"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-requests' 'python2-requests' 'git')
+checkdepends=('python-nose' 'python2-nose')
+source=("git+https://github.com/braintree/braintree_python.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a braintree_python{,-py2}
+}
+
+build() {
+  cd "$srcdir"/braintree_python
+  python setup.py build
+
+  cd "$srcdir"/braintree_python-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/braintree_python
+  nosetests3 tests/unit
+
+  cd "$srcdir"/braintree_python-py2
+  nosetests2 tests/unit
+}
+
+package_python-braintree() {
+  depends=('python-requests')
+
+  cd braintree_python
+  python setup.py install -O1 --root="$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-braintree() {
+  depends=('python2-requests')
+
+  cd braintree_python-py2
+  python2 setup.py install -O1 --root="$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}