[arch-commits] Commit in python-paramiko/repos (2 files)

[Bartłomiej Piotrowski]

    Date: Sunday, December 25, 2016 @ 18:16:03
  Author: bpiotrowski
Revision: 202233

archrelease: copy trunk to community-staging-any

Added:
  python-paramiko/repos/community-staging-any/
  python-paramiko/repos/community-staging-any/PKGBUILD
    (from rev 202232, python-paramiko/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: python-paramiko/repos/community-staging-any/PKGBUILD (from rev 202232, python-paramiko/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-25 18:16:03 UTC (rev 202233)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Angel Velasquez <angvp at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Douglas Soares de Andrade <douglas at archlinux.org>
+# Contributor: Mario Danic <mario.danic at gmail.com>
+
+pkgbase=python-paramiko
+pkgname=(python-paramiko python2-paramiko)
+pkgver=2.1.1
+pkgrel=2
+pkgdesc="Python module that implements the SSH2 protocol"
+url="https://github.com/paramiko/paramiko/"
+license=('LGPL')
+arch=('any')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-cryptography' 'python2-cryptography' 'git')
+source=("git+https://github.com/paramiko/paramiko.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a paramiko{,-py2}
+
+  find paramiko-py2 -name '*.py' -print0 | xargs -0 \
+    sed -i -e 's,^#!/usr/bin/env python$,#!/usr/bin/env python2,' \
+        -e 's,^#!/usr/bin/python$,#!/usr/bin/python2,'
+}
+
+check() {
+  cd "$srcdir/paramiko"
+  LANG=en_US.UTF-8 python test.py
+
+  cd "$srcdir/paramiko-py2"
+  LANG=en_US.UTF-8 python2 test.py
+}
+
+package_python-paramiko() {
+  depends=('python-setuptools' 'python-cryptography')
+  cd "$srcdir/paramiko"
+
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -dm755 "$pkgdir/usr/share/doc/$pkgname/demos"
+  install -m644 demos/* "$pkgdir/usr/share/doc/$pkgname/demos"
+  chmod 755 "$pkgdir/usr/share/doc/$pkgname/demos/"*.py
+}
+
+package_python2-paramiko() {
+  depends=('python2-setuptools' 'python2-cryptography')
+  cd "$srcdir/paramiko-py2"
+
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -dm755 "$pkgdir/usr/share/doc/$pkgname/demos"
+  install -m644 demos/* "$pkgdir/usr/share/doc/$pkgname/demos"
+  chmod 755 "$pkgdir/usr/share/doc/$pkgname/demos/"*.py
+}
+