[arch-commits] Commit in python-nose-exclude/repos (2 files)

[Bartłomiej Piotrowski]

    Date: Sunday, December 25, 2016 @ 18:52:41
  Author: bpiotrowski
Revision: 202284

archrelease: copy trunk to community-staging-any

Added:
  python-nose-exclude/repos/community-staging-any/
  python-nose-exclude/repos/community-staging-any/PKGBUILD
    (from rev 202283, python-nose-exclude/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: python-nose-exclude/repos/community-staging-any/PKGBUILD (from rev 202283, python-nose-exclude/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-25 18:52:41 UTC (rev 202284)
@@ -0,0 +1,48 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-nose-exclude
+pkgname=("python-nose-exclude" "python2-nose-exclude")
+pkgver=0.5.0
+pkgrel=2
+pkgdesc="Exclude specific directories from nosetests runs"
+arch=('any')
+url="https://github.com/kgrandis/nose-exclude"
+license=('LGPL')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-nose' 'python2-nose' 'git')
+source=("git+https://github.com/kgrandis/nose-exclude.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a nose-exclude{,-py2}
+}
+
+build() {
+  cd "$srcdir"/nose-exclude
+  python setup.py build
+
+  cd "$srcdir"/nose-exclude-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/nose-exclude
+  python setup.py test
+
+  cd "$srcdir"/nose-exclude-py2
+  python2 setup.py test
+}
+
+package_python-nose-exclude() {
+  depends=('python-nose')
+
+  cd nose-exclude
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-nose-exclude() {
+  depends=('python2-nose')
+
+  cd nose-exclude-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}