[arch-commits] Commit in twine/repos (2 files)

[Bartłomiej Piotrowski]

    Date: Monday, December 26, 2016 @ 10:12:15
  Author: bpiotrowski
Revision: 202689

archrelease: copy trunk to community-staging-any

Added:
  twine/repos/community-staging-any/
  twine/repos/community-staging-any/PKGBUILD
    (from rev 202688, twine/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: twine/repos/community-staging-any/PKGBUILD (from rev 202688, twine/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-26 10:12:15 UTC (rev 202689)
@@ -0,0 +1,59 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Chris Warrick <aur at chriswarrick.com>
+
+pkgbase=twine
+pkgname=('twine' 'python2-twine')
+pkgver=1.8.1
+pkgrel=2
+pkgdesc='Collection of utilities for interacting with PyPI'
+arch=('any')
+url='https://pypi.python.org/pypi/twine'
+license=('Apache')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-clint' 'python2-clint'
+             'python-requests-toolbelt' 'python2-requests-toolbelt' 'python-pkginfo'
+             'python2-pkginfo' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-pretend' 'python2-pretend')
+source=("git+https://github.com/pypa/twine.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a twine{,-py2}
+}
+
+build() {
+  cd "$srcdir"/twine
+  python setup.py build
+
+  cd "$srcdir"/twine-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/twine
+  python setup.py ptr
+
+  cd "$srcdir"/twine-py2
+  python2 setup.py ptr
+}
+
+package_twine() {
+  depends=('python-setuptools' 'python-requests-toolbelt' 'python-pkginfo' 'python-clint')
+  provides=('python-twine')
+  conflicts=('python-twine')
+  replaces=('python-twine')
+
+  cd twine
+  python3 setup.py install --root="$pkgdir" --optimize=1
+  ln -s twine "$pkgdir"/usr/bin/twine3
+}
+
+package_python2-twine() {
+  depends=('python2-setuptools' 'python2-requests-toolbelt' 'python2-pkginfo' 'python2-clint')
+
+  cd twine-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  mv "$pkgdir"/usr/bin/twine{,2}
+}
+
+# vim:set ts=2 sw=2 et: