[arch-commits] Commit in qutebrowser/repos (2 files)

[Bartłomiej Piotrowski]

    Date: Tuesday, December 27, 2016 @ 06:36:57
  Author: bpiotrowski
Revision: 202948

archrelease: copy trunk to community-staging-any

Added:
  qutebrowser/repos/community-staging-any/
  qutebrowser/repos/community-staging-any/PKGBUILD
    (from rev 202947, qutebrowser/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: qutebrowser/repos/community-staging-any/PKGBUILD (from rev 202947, qutebrowser/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-27 06:36:57 UTC (rev 202948)
@@ -0,0 +1,48 @@
+# Maintainer: Pierre Neidhardt <ambrevar at gmail.com>
+# Contributor: Florian Bruhin (The Compiler) <archlinux.org at the-compiler.org>
+
+pkgname=qutebrowser
+pkgver=0.8.4
+pkgrel=2
+pkgdesc="A keyboard-driven, vim-like browser based on PyQt5 and QtWebKit"
+arch=("any")
+url="http://www.qutebrowser.org/"
+license=("GPL")
+depends=("desktop-file-utils" "hicolor-icon-theme" "libxkbcommon-x11"
+	"python-jinja" "python-pygments" "python-pypeg2" "python-pyqt5>=5.2"
+	"python-yaml" "qt5-base>=5.2" "qt5-webkit>=5.2" "xdg-utils")
+makedepends=("asciidoc")
+optdepends=("python-colorlog: colored logging output"
+	"gst-libav: media playback"
+	"gst-plugins-base: media playback"
+	"gst-plugins-good: media playback"
+	"gst-plugins-bad: media playback"
+	"gst-plugins-ugly: media playback"
+	"pdfjs: Displaying PDF in-browser")
+options=(!emptydirs)
+source=("https://qutebrowser.org/releases/v$pkgver/qutebrowser-$pkgver.tar.gz"
+	"https://qutebrowser.org/releases/v$pkgver/qutebrowser-$pkgver.tar.gz.asc")
+validpgpkeys=("E04E560002401B8EF0E76F0A916EB0C8FD55A072")
+sha256sums=('f5ce98c5bc57ae29dc31f8896fad6911feab91277a9554761126219e0f8e8671'
+            'SKIP')
+
+build() {
+	cd "$srcdir/$pkgname-$pkgver"
+	a2x -f manpage doc/qutebrowser.1.asciidoc
+	python setup.py build
+}
+
+package() {
+	cd "$srcdir/$pkgname-$pkgver"
+	python setup.py install --root="$pkgdir/" --optimize=1
+	install -Dm644 doc/qutebrowser.1 "$pkgdir/usr/share/man/man1/qutebrowser.1"
+	install -Dm644 qutebrowser.desktop \
+		"$pkgdir/usr/share/applications/qutebrowser.desktop"
+	for i in 16 24 32 48 64 128 256 512; do
+		install -Dm644 "icons/qutebrowser-${i}x$i.png" \
+			"$pkgdir/usr/share/icons/hicolor/${i}x$i/apps/qutebrowser.png"
+	done
+	install -Dm644 icons/qutebrowser.svg \
+		"$pkgdir/usr/share/icons/hicolor/scalable/apps/qutebrowser.svg"
+	install -Dm755 -t "$pkgdir/usr/share/qutebrowser/userscripts/" misc/userscripts/*
+}