[arch-commits] Commit in python-flask-socketio/repos (2 files)

[Felix Yan]

    Date: Tuesday, December 27, 2016 @ 06:40:52
  Author: felixonmars
Revision: 202962

archrelease: copy trunk to community-staging-any

Added:
  python-flask-socketio/repos/community-staging-any/
  python-flask-socketio/repos/community-staging-any/PKGBUILD
    (from rev 202961, python-flask-socketio/trunk/PKGBUILD)

----------+
 PKGBUILD |   63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

Copied: python-flask-socketio/repos/community-staging-any/PKGBUILD (from rev 202961, python-flask-socketio/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-27 06:40:52 UTC (rev 202962)
@@ -0,0 +1,63 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgbase=python-flask-socketio
+pkgname=('python-flask-socketio' 'python2-flask-socketio')
+_pkgname=Flask-SocketIO
+pkgver=2.8.2
+pkgrel=2
+pkgdesc='Socket.IO integration for Flask applications'
+url='https://flask-socketio.readthedocs.org/'
+arch=('any')
+license=('MIT')
+makedepends=('python-setuptools' 'python-sphinx' 'python-flask' 'python-eventlet' 'python-socketio'
+             'python2-setuptools' 'python2-sphinx' 'python2-flask' 'python2-eventlet' 'python2-socketio')
+checkdepends=('python-coverage' 'python-pytest' 'python2-coverage' 'python2-pytest')
+options=('!makeflags')
+source=(${pkgbase}-${pkgver}.tar.gz::https://github.com/miguelgrinberg/Flask-SocketIO/archive/v${pkgver}.tar.gz)
+sha512sums=('35424b87222aa82384e358ec5a51b8d7d723c324065ad231f55e4a7c8ed6ba7bd9dbc3e6b0be6ade073c0333cd81f9eb317fc618a54104c6b3767914647e7e87')
+
+prepare() {
+  cp -ra ${_pkgname}-${pkgver}{,-py2}
+}
+
+build() {
+  (cd ${_pkgname}-${pkgver}
+    python setup.py build
+    make -C docs man text SPHINXBUILD=sphinx-build
+  )
+  (cd ${_pkgname}-${pkgver}-py2
+    python2 setup.py build
+    make -C docs man text SPHINXBUILD=sphinx-build2
+  )
+}
+
+check() {
+  (cd ${_pkgname}-${pkgver}
+    py.test test_socketio.py
+  )
+  (cd ${_pkgname}-${pkgver}-py2
+    py.test2 test_socketio.py
+  )
+}
+
+package_python-flask-socketio() {
+  depends=('python-flask' 'python-eventlet' 'python-socketio')
+  cd ${_pkgname}-${pkgver}
+  python setup.py install -O1 --root="${pkgdir}" --skip-build
+  install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm 644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README"
+  install -Dm 644 docs/_build/text/index.txt "${pkgdir}/usr/share/doc/${pkgname}/DOCUMENTATION"
+  install -Dm 644 docs/_build/man/flask-socketio.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+package_python2-flask-socketio() {
+  depends=('python2-flask' 'python2-eventlet' 'python-socketio')
+  cd ${_pkgname}-${pkgver}-py2
+  python2 setup.py install -O1 --root="${pkgdir}" --skip-build
+  install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm 644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README"
+  install -Dm 644 docs/_build/text/index.txt "${pkgdir}/usr/share/doc/${pkgname}/DOCUMENTATION"
+  install -Dm 644 docs/_build/man/flask-socketio.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+# vim: ts=2 sw=2 et: