[arch-commits] Commit in python-jsonpickle/repos (2 files)

[Felix Yan]

    Date: Tuesday, December 27, 2016 @ 06:51:49
  Author: felixonmars
Revision: 202982

archrelease: copy trunk to community-staging-any

Added:
  python-jsonpickle/repos/community-staging-any/
  python-jsonpickle/repos/community-staging-any/PKGBUILD
    (from rev 202981, python-jsonpickle/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: python-jsonpickle/repos/community-staging-any/PKGBUILD (from rev 202981, python-jsonpickle/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-27 06:51:49 UTC (rev 202982)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-jsonpickle
+pkgname=(python-jsonpickle python2-jsonpickle)
+pkgver=0.9.3
+pkgrel=2
+arch=('any')
+pkgdesc="Python library for serializing any arbitrary object graph into JSON"
+url="http://jsonpickle.github.io/"
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-nose-show-skipped' 'python2-nose-show-skipped' 'python-numpy' 'python2-numpy'
+              'python-feedparser' 'python2-feedparser' 'python-coverage' 'python2-coverage' 'python2-enum34'
+              'python-simplejson' 'python2-simplejson' 'python-pymongo' 'python2-pymongo' 'python-ujson'
+              'python2-ujson')
+license=('BSD')
+source=("https://pypi.python.org/packages/source/j/jsonpickle/jsonpickle-$pkgver.tar.gz")
+md5sums=('cb30198969da11f9d19a11d03e0d0046')
+
+prepare() {
+  cp -a jsonpickle-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/jsonpickle-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/jsonpickle-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/jsonpickle-$pkgver
+  nosetests3 --show-skipped
+
+  cd "$srcdir"/jsonpickle-$pkgver-py2
+  nosetests2 --show-skipped
+}
+
+package_python-jsonpickle() {
+  depends=('python')
+
+  cd jsonpickle-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
+}
+
+package_python2-jsonpickle() {
+  depends=('python2')
+
+  cd jsonpickle-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
+}