[arch-commits] Commit in python-zope-configuration/repos (2 files)

Felix Yan felixonmars at archlinux.org
Tue Dec 27 08:02:31 UTC 2016


    Date: Tuesday, December 27, 2016 @ 08:02:30
  Author: felixonmars
Revision: 203018

archrelease: copy trunk to community-staging-any

Added:
  python-zope-configuration/repos/community-staging-any/
  python-zope-configuration/repos/community-staging-any/PKGBUILD
    (from rev 203016, python-zope-configuration/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: python-zope-configuration/repos/community-staging-any/PKGBUILD (from rev 203016, python-zope-configuration/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2016-12-27 08:02:30 UTC (rev 203018)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=('python-zope-configuration' 'python2-zope-configuration')
+pkgver=4.0.3
+pkgrel=2
+pkgdesc="Zope Configuration Markup Language (ZCML)"
+arch=('any')
+url="https://github.com/zopefoundation/zope.configuration"
+license=('ZPL')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-zope-interface'
+             'python2-zope-interface' 'python-zope-schema' 'python2-zope-schema'
+             'python-zope-i18nmessageid' 'python2-zope-i18nmessageid' 'git')
+checkdepends=('python-nose' 'python2-nose')
+source=("git+https://github.com/zopefoundation/zope.configuration.git#tag=$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -a zope.configuration{,-py2}
+}
+
+build() {
+  cd "$srcdir/zope.configuration"
+  python setup.py build
+
+  cd "$srcdir/zope.configuration-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/zope.configuration"
+  nosetests3
+
+  cd "$srcdir/zope.configuration-py2"
+  nosetests2
+}
+
+package_python-zope-configuration() {
+  depends=('python-setuptools' 'python-zope-interface' 'python-zope-schema'
+           'python-zope-i18nmessageid')
+
+  cd "$srcdir/zope.configuration"
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-zope-configuration() {
+  depends=('python2-setuptools' 'python2-zope-interface' 'python2-zope-schema'
+           'python2-zope-i18nmessageid')
+
+  cd "$srcdir/zope.configuration-py2"
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et:



More information about the arch-commits mailing list