[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Thursday, February 4, 2016 @ 04:22:50
  Author: fyan
Revision: 160164

addpkg: python-nose-fixes 1.3-1

Added:
  python-nose-fixes/
  python-nose-fixes/repos/
  python-nose-fixes/trunk/
  python-nose-fixes/trunk/PKGBUILD

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Added: python-nose-fixes/trunk/PKGBUILD
===================================================================
--- python-nose-fixes/trunk/PKGBUILD	                        (rev 0)
+++ python-nose-fixes/trunk/PKGBUILD	2016-02-04 03:22:50 UTC (rev 160164)
@@ -0,0 +1,49 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-nose-fixes
+pkgname=("python-nose-fixes" "python2-nose-fixes")
+pkgver=1.3
+pkgrel=1
+pkgdesc="A plugin to make nose behave better"
+arch=('any')
+url="https://github.com/cjw296/nose_fixes"
+license=('LGPL')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-nose' 'python2-nose' 'git')
+checkdepends=('python-testfixtures' 'python2-testfixtures')
+source=("git+https://github.com/cjw296/nose_fixes.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a "nose_fixes"{,-py2}
+}
+
+build() {
+  cd "$srcdir/nose_fixes"
+  python setup.py build
+
+  cd "$srcdir/nose_fixes-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/nose_fixes"
+  nosetests3
+
+  cd "$srcdir/nose_fixes-py2"
+  nosetests2
+}
+
+package_python-nose-fixes() {
+  depends=('python-nose')
+
+  cd nose_fixes
+  python setup.py install --root="${pkgdir}" --optimize=1
+}
+
+package_python2-nose-fixes() {
+  depends=('python2-nose')
+
+  cd nose_fixes-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+}


Property changes on: python-nose-fixes/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property