[arch-commits] Commit in python-cached-property/repos (2 files)

[Felix Yan]

    Date: Friday, February 5, 2016 @ 03:54:14
  Author: fyan
Revision: 160365

archrelease: copy trunk to community-any

Added:
  python-cached-property/repos/community-any/
  python-cached-property/repos/community-any/PKGBUILD
    (from rev 160364, python-cached-property/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: python-cached-property/repos/community-any/PKGBUILD (from rev 160364, python-cached-property/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2016-02-05 02:54:14 UTC (rev 160365)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-cached-property
+pkgname=('python-cached-property' 'python2-cached-property')
+pkgver=1.3.0
+pkgrel=1
+pkgdesc="A decorator for caching properties in classes"
+arch=('any')
+license=('BSD')
+url="https://github.com/pydanny/cached-property"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest' 'python2-pytest' 'python-freezegun' 'python2-freezegun')
+source=("git+https://github.com/pydanny/cached-property.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a cached-property{,-py2}
+}
+
+build() {
+  cd "$srcdir/cached-property"
+  python setup.py build
+
+  cd "$srcdir/cached-property-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/cached-property"
+  py.test
+
+  cd "$srcdir/cached-property-py2"
+  py.test2
+}
+
+package_python-cached-property() {
+  depends=('python')
+
+  cd cached-property
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-cached-property() {
+  depends=('python2')
+
+  cd cached-property-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}