[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Saturday, February 6, 2016 @ 01:48:19
  Author: fyan
Revision: 160445

addpkg: python-keyrings-alt 1.1.20160123-1

Added:
  python-keyrings-alt/
  python-keyrings-alt/repos/
  python-keyrings-alt/trunk/
  python-keyrings-alt/trunk/PKGBUILD

----------+
 PKGBUILD |   71 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)

Added: python-keyrings-alt/trunk/PKGBUILD
===================================================================
--- python-keyrings-alt/trunk/PKGBUILD	                        (rev 0)
+++ python-keyrings-alt/trunk/PKGBUILD	2016-02-06 00:48:19 UTC (rev 160445)
@@ -0,0 +1,71 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Johannes Dewender  arch at JonnyJD dot net
+# Contributor: Ivan Sichmann Freitas <ivansichfreitas at gmail.com>
+# Contributor: Brice Maron <brice at bmaron.net>
+# Contributor: Nuno Araujo <nuno.araujo at russo79.com>
+# Contributor: Steven Allen <steven {at} stebalien {dot} com>
+
+pkgbase=python-keyrings-alt
+pkgname=('python-keyrings-alt' 'python2-keyrings-alt')
+pkgver=1.1.20160123
+_commit=b91f7d765b8045a16cac993c6f0a5eac1322e8d8
+pkgrel=1
+pkgdesc="Alternate keyring implementations"
+arch=('any')
+url="http://pypi.python.org/pypi/keyrings.alt"
+license=('MIT')
+source=("git+https://github.com/jaraco/keyrings.alt.git#commit=$_commit")
+makedepends=('python-setuptools_scm' 'python2-setuptools_scm' 'python-keyring' 'python2-keyring' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-mock' 'python2-mock'
+              'python-fs' 'python2-fs' 'python-crypto' 'python2-crypto' 'libgnome-keyring' 
+              'python-gobject' 'python2-gobject' 'python2-gdata')
+md5sums=('SKIP')
+
+prepare() {
+  # Remove it from test_requirements
+  sed -i '/python-keyczar/d' keyrings.alt/setup.py
+
+  cp -a keyrings.alt{,-py2}
+}
+
+build() {
+  cd "$srcdir/keyrings.alt"
+  python setup.py build
+
+  cd "$srcdir/keyrings.alt-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/keyrings.alt"
+  python setup.py ptr
+
+  cd "$srcdir/keyrings.alt-py2"
+  python2 setup.py ptr
+}
+
+package_python-keyrings-alt() {
+  depends=('python-keyring')
+  optdepends=('libgnome-keyring: GNOME Integration'
+              'python-gobject: GNOME Integration'
+              'python-fs'
+              'python-crypto: Encrypted file storage')
+
+  cd "$srcdir/keyrings.alt"
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-keyrings-alt() {
+  depends=('python2-keyring')
+  optdepends=('libgnome-keyring: GNOME Integration'
+              'python2-gobject: GNOME Integration'
+              'python2-fs'
+              'python2-gdata: Google Docs Integration'
+              'python2-crypto: Encrypted file storage')
+
+  cd "$srcdir/keyrings.alt-py2"
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et:


Property changes on: python-keyrings-alt/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property