[arch-commits] Commit in python-hyperframe/repos (2 files)

Felix Yan fyan at archlinux.org
Mon Feb 15 00:08:13 UTC 2016


    Date: Monday, February 15, 2016 @ 01:08:13
  Author: fyan
Revision: 161564

archrelease: copy trunk to community-any

Added:
  python-hyperframe/repos/community-any/
  python-hyperframe/repos/community-any/PKGBUILD
    (from rev 161563, python-hyperframe/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: python-hyperframe/repos/community-any/PKGBUILD (from rev 161563, python-hyperframe/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2016-02-15 00:08:13 UTC (rev 161564)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-hyperframe
+pkgname=('python-hyperframe' 'python2-hyperframe')
+pkgver=3.2.0
+pkgrel=1
+pkgdesc="HTTP/2 framing layer for Python"
+arch=('any')
+license=('MIT')
+url="http://hyper.rtfd.org"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("git+https://github.com/python-hyper/hyperframe.git#tag=v$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a hyperframe{,-py2}
+}
+
+build() {
+  cd "$srcdir/hyperframe"
+  python setup.py build
+
+  cd "$srcdir/hyperframe-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/hyperframe"
+  python setup.py ptr
+
+  cd "$srcdir/hyperframe-py2"
+  python2 setup.py ptr
+}
+
+package_python-hyperframe() {
+  depends=('python')
+
+  cd hyperframe
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-hyperframe() {
+  depends=('python2')
+
+  cd hyperframe-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+



More information about the arch-commits mailing list