[arch-commits] Commit in python-h2/repos (community-any community-any/PKGBUILD)
Felix Yan
fyan at archlinux.org
Mon Feb 15 00:21:45 UTC 2016
Date: Monday, February 15, 2016 @ 01:21:45
Author: fyan
Revision: 161570
archrelease: copy trunk to community-any
Added:
python-h2/repos/community-any/
python-h2/repos/community-any/PKGBUILD
(from rev 161569, python-h2/trunk/PKGBUILD)
----------+
PKGBUILD | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 54 insertions(+)
Copied: python-h2/repos/community-any/PKGBUILD (from rev 161569, python-h2/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD (rev 0)
+++ community-any/PKGBUILD 2016-02-15 00:21:45 UTC (rev 161570)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-h2
+pkgname=('python-h2' 'python2-h2')
+pkgver=2.1.1
+pkgrel=1
+pkgdesc="HTTP/2 State-Machine based protocol implementation"
+arch=('any')
+license=('MIT')
+url="http://hyper.rtfd.org"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-hpack' 'python2-hpack'
+ 'python-hyperframe' 'python2-hyperframe' 'python2-enum34' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-hypothesis'
+ 'python2-hypothesis')
+source=("git+https://github.com/python-hyper/hyper-h2.git#tag=v$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+ sed -i 's/enum34>=1.0.4, <1.1/enum34>=1.0.4, <1.2/' hyper-h2/setup.py
+ cp -a hyper-h2{,-py2}
+}
+
+build() {
+ cd "$srcdir/hyper-h2"
+ python setup.py build
+
+ cd "$srcdir/hyper-h2-py2"
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir/hyper-h2"
+ python setup.py ptr
+
+ cd "$srcdir/hyper-h2-py2"
+ python2 setup.py ptr
+}
+
+package_python-h2() {
+ depends=('python-hpack' 'python-hyperframe')
+
+ cd hyper-h2
+ python setup.py install --root="${pkgdir}" --optimize=1
+ install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-h2() {
+ depends=('python2-hpack' 'python2-hyperframe' 'python2-enum34')
+
+ cd hyper-h2-py2
+ python2 setup.py install --root="${pkgdir}" --optimize=1
+ install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
More information about the arch-commits
mailing list