[arch-commits] Commit in lib32-libdrm/repos (2 files)
Laurent Carlier
lcarlier at archlinux.org
Tue Feb 16 12:21:56 UTC 2016
Date: Tuesday, February 16, 2016 @ 13:21:56
Author: lcarlier
Revision: 161827
archrelease: copy trunk to multilib-testing-x86_64
Added:
lib32-libdrm/repos/multilib-testing-x86_64/
lib32-libdrm/repos/multilib-testing-x86_64/PKGBUILD
(from rev 161826, lib32-libdrm/trunk/PKGBUILD)
----------+
PKGBUILD | 57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 57 insertions(+)
Copied: lib32-libdrm/repos/multilib-testing-x86_64/PKGBUILD (from rev 161826, lib32-libdrm/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD (rev 0)
+++ multilib-testing-x86_64/PKGBUILD 2016-02-16 12:21:56 UTC (rev 161827)
@@ -0,0 +1,57 @@
+# $Id$
+# Maintainer: Laurent Carlier <lordheavym at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+_pkgbasename=libdrm
+pkgname=lib32-$_pkgbasename
+pkgver=2.4.67
+pkgrel=1
+pkgdesc="Userspace interface to kernel DRM services (32-bit)"
+arch=(x86_64)
+license=('custom')
+depends=('lib32-libpciaccess' $_pkgbasename)
+makedepends=(gcc-multilib xorg-util-macros valgrind-multilib)
+options=('!libtool')
+url="http://dri.freedesktop.org/"
+source=(http://dri.freedesktop.org/${_pkgbasename}/${_pkgbasename}-${pkgver}.tar.bz2{,.sig})
+sha256sums=('ee5b71e1113be37544d0752681c12f040c01f782e2933df7d7bc21fd0d10cebe'
+ 'SKIP')
+validpgpkeys=('B97BD6A80CAC4981091AE547FE558C72A67013C3') # Maarten Lankhorst <maarten.lankhorst at canonical.com>
+validpgpkeys+=('215DEE688925CCB965BE5DA97C03D7797B6E1AE2') # Damien Lespiau <damien.lespiau at intel.com>
+validpgpkeys+=('10A6D91DA1B05BD29F6DEBAC0C74F35979C486BE') # David Airlie <airlied at redhat.com>
+validpgpkeys+=('8703B6700E7EE06D7A39B8D6EDAE37B02CEB490D') # Emil Velikov <emil.l.velikov at gmail.com>
+validpgpkeys+=('D6285B5E899299F3DA746184191C9B905522B045') # Rob Clark <robclark at freedesktop.org>
+
+build() {
+ cd "${srcdir}/${_pkgbasename}-${pkgver}"
+
+ export CC="gcc -m32"
+ export CXX="g++ -m32"
+ export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+ # pthread is useless in Linux
+ sed -i "/pthread-stubs/d" configure.ac
+ autoreconf --force --install
+
+ ./configure --prefix=/usr \
+ --libdir=/usr/lib32 \
+ --enable-udev
+
+ make
+}
+
+check() {
+ cd "${srcdir}/${_pkgbasename}-${pkgver}"
+ make -k check
+}
+
+package() {
+ cd "${srcdir}/${_pkgbasename}-${pkgver}"
+
+ make DESTDIR="${pkgdir}" install
+
+ rm -rf "${pkgdir}"/usr/{include,share,bin}
+ mkdir -p "$pkgdir/usr/share/licenses"
+ ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
+}
+
More information about the arch-commits
mailing list