[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, February 19, 2016 @ 06:25:44
  Author: fyan
Revision: 162411

addpkg: autopep8 1.2.1-1

Added:
  autopep8/
  autopep8/repos/
  autopep8/trunk/
  autopep8/trunk/PKGBUILD

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Added: autopep8/trunk/PKGBUILD
===================================================================
--- autopep8/trunk/PKGBUILD	                        (rev 0)
+++ autopep8/trunk/PKGBUILD	2016-02-19 05:25:44 UTC (rev 162411)
@@ -0,0 +1,59 @@
+# $Id: PKGBUILD 156190 2016-01-13 01:59:24Z fyan $
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Ismael Carnales <icarnales at gmail dot com>
+# Contributor: Sergey Mastykov <smastykov[at]gmail[dot]com>
+
+pkgbase=autopep8
+pkgname=(autopep8 python2-autopep8)
+pkgver=1.2.1
+pkgrel=1
+pkgdesc="A tool that automatically formats Python code to conform to the PEP 8 style guide"
+arch=('any')
+url="http://github.com/hhatto/autopep8"
+license=('MIT')
+makedepends=('pep8' 'python2-pep8' 'git')
+source=("git+https://github.com/hhatto/autopep8.git#tag=ver$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -a autopep8{,-py2}
+}
+
+build() {
+  cd "$srcdir"/autopep8
+  python setup.py build
+
+  cd "$srcdir"/autopep8-py2
+  python2 setup.py build
+}
+
+check() {
+  export LC_CTYPE=en_US.UTF-8
+
+  cd "$srcdir"/autopep8
+  python setup.py test
+
+  cd "$srcdir"/autopep8-py2
+  python2 setup.py test
+}
+
+package_autopep8() {
+  depends=('pep8')
+
+  cd autopep8
+  python3 setup.py install -O1 --prefix=/usr --root="$pkgdir/"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-autopep8() {
+  depends=('python2-pep8')
+
+  cd autopep8-py2
+  python2 setup.py install -O1 --prefix=/usr --root="$pkgdir/"
+  mv "$pkgdir/usr/bin/autopep8" "$pkgdir/usr/bin/autopep8-python2"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et: