[arch-commits] Commit in autopep8/repos (community-any community-any/PKGBUILD)

[Felix Yan]

    Date: Friday, February 19, 2016 @ 06:26:02
  Author: fyan
Revision: 162412

archrelease: copy trunk to community-any

Added:
  autopep8/repos/community-any/
  autopep8/repos/community-any/PKGBUILD
    (from rev 162411, autopep8/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: autopep8/repos/community-any/PKGBUILD (from rev 162411, autopep8/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2016-02-19 05:26:02 UTC (rev 162412)
@@ -0,0 +1,59 @@
+# $Id: PKGBUILD 156190 2016-01-13 01:59:24Z fyan $
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Ismael Carnales <icarnales at gmail dot com>
+# Contributor: Sergey Mastykov <smastykov[at]gmail[dot]com>
+
+pkgbase=autopep8
+pkgname=(autopep8 python2-autopep8)
+pkgver=1.2.1
+pkgrel=1
+pkgdesc="A tool that automatically formats Python code to conform to the PEP 8 style guide"
+arch=('any')
+url="http://github.com/hhatto/autopep8"
+license=('MIT')
+makedepends=('pep8' 'python2-pep8' 'git')
+source=("git+https://github.com/hhatto/autopep8.git#tag=ver$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -a autopep8{,-py2}
+}
+
+build() {
+  cd "$srcdir"/autopep8
+  python setup.py build
+
+  cd "$srcdir"/autopep8-py2
+  python2 setup.py build
+}
+
+check() {
+  export LC_CTYPE=en_US.UTF-8
+
+  cd "$srcdir"/autopep8
+  python setup.py test
+
+  cd "$srcdir"/autopep8-py2
+  python2 setup.py test
+}
+
+package_autopep8() {
+  depends=('pep8')
+
+  cd autopep8
+  python3 setup.py install -O1 --prefix=/usr --root="$pkgdir/"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-autopep8() {
+  depends=('python2-pep8')
+
+  cd autopep8-py2
+  python2 setup.py install -O1 --prefix=/usr --root="$pkgdir/"
+  mv "$pkgdir/usr/bin/autopep8" "$pkgdir/usr/bin/autopep8-python2"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et: