[arch-commits] Commit in (4 files)

Felix Yan fyan at archlinux.org
Sat Feb 20 13:43:10 UTC 2016


    Date: Saturday, February 20, 2016 @ 14:43:09
  Author: fyan
Revision: 162721

addpkg: python-requests-mock 0.7.0-1

Added:
  python-requests-mock/
  python-requests-mock/repos/
  python-requests-mock/trunk/
  python-requests-mock/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: python-requests-mock/trunk/PKGBUILD
===================================================================
--- python-requests-mock/trunk/PKGBUILD	                        (rev 0)
+++ python-requests-mock/trunk/PKGBUILD	2016-02-20 13:43:09 UTC (rev 162721)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-requests-mock
+pkgname=('python-requests-mock' 'python2-requests-mock')
+pkgver=0.7.0
+pkgrel=1
+pkgdesc="A mock of useful classes and functions to be used with python-requests."
+arch=('any')
+url="https://github.com/openstack/requests-mock"
+license=('Apache')
+makedepends=('python-pbr' 'python2-pbr' 'python-requests' 'python2-requests'
+             'python-six' 'python2-six' 'git')
+checkdepends=('python-testrepository' 'python2-testrepository' 'python-mock' 'python2-mock')
+source=("git+https://github.com/openstack/requests-mock.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a requests-mock{,-py2}
+}
+
+build() {
+  cd "$srcdir/requests-mock"
+  python setup.py build
+
+  cd "$srcdir/requests-mock-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/requests-mock"
+  python setup.py testr
+
+  cd "$srcdir/requests-mock-py2"
+  python2 setup.py testr
+}
+
+package_python-requests-mock() {
+  depends=('python-requests' 'python-six')
+
+  cd "$srcdir/requests-mock"
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-requests-mock() {
+  depends=('python2-requests' 'python2-six')
+
+  cd "$srcdir/requests-mock-py2"
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}


Property changes on: python-requests-mock/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list