[arch-commits] Commit in (4 files)

Felix Yan fyan at archlinux.org
Tue Feb 23 03:25:21 UTC 2016


    Date: Tuesday, February 23, 2016 @ 04:25:21
  Author: fyan
Revision: 163166

addpkg: python-mox3 0.14.0-1

Added:
  python-mox3/
  python-mox3/repos/
  python-mox3/trunk/
  python-mox3/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: python-mox3/trunk/PKGBUILD
===================================================================
--- python-mox3/trunk/PKGBUILD	                        (rev 0)
+++ python-mox3/trunk/PKGBUILD	2016-02-23 03:25:21 UTC (rev 163166)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-mox3
+pkgname=('python-mox3' 'python2-mox3')
+pkgver=0.14.0
+pkgrel=1
+arch=('any')
+pkgdesc='Mock object framework for Python'
+url='http://docs.openstack.org/developer/mox3'
+license=('Apache')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-pbr' 'python2-pbr'
+             'python-fixtures' 'python2-fixtures' 'git')
+checkdepends=('python-testrepository' 'python2-testrepository')
+source=("git+https://git.openstack.org/openstack/mox3#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a mox3{,-py2}
+}
+
+build() {
+  cd "$srcdir"/mox3
+  python setup.py build
+
+  cd "$srcdir"/mox3-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/mox3
+  python setup.py testr
+
+  cd "$srcdir"/mox3-py2
+  python2 setup.py testr
+}
+
+package_python-mox3() {
+  depends=('python-pbr' 'python-fixtures')
+
+  cd mox3
+  python setup.py install --root "$pkgdir" --optimize=1
+}
+
+package_python2-mox3() {
+  depends=('python2-pbr' 'python2-fixtures')
+
+  cd mox3-py2
+  python2 setup.py install --root "$pkgdir" --optimize=1
+}


Property changes on: python-mox3/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list